nonprism/evolution-data-server-nonprism/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# $Id: PKGBUILD 196433 2013-10-13 19:19:09Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

_pkgname=evolution-data-server
pkgname=evolution-data-server-nonprism
pkgver=3.10.1
pkgrel=1
pkgdesc="Centralized access to appointments and contacts, without libgdata support"
arch=(i686 x86_64)
depends=(gnome-online-accounts nss krb5 libgweather libical db gcr libsoup)
makedepends=(intltool gperf gobject-introspection vala python2)
options=('!libtool')
install=$_pkgname.install
url="http://www.gnome.org"
license=(GPL)
replaces=("$_pkgname" 'evolution-data-server-coherence')
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=(http://ftp.gnome.org/pub/gnome/sources/$_pkgname/${pkgver%.*}/$_pkgname-$pkgver.tar.xz)
sha256sums=('a6b5acbd21767b685d58ebfd4c152baa693387f5654fb738b3645ee39e82f9f5')

build() {
  cd "$_pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --with-openldap=yes \
      --libexecdir=/usr/lib/evolution-data-server \
      --with-krb5=/usr --with-libdb=/usr \
      --without-libgdata \
      --disable-google \
      --enable-vala-bindings --disable-uoa
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
  make
}

package() {
  cd "$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}