blob: eb2912173dbfab07f66e628ea13c22ef7539d45e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id$
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Maintainers: Parabola hackers <dev@lists.parabola.nu>
# parabola changes and rationale
# - removed geoclue2 support
pkgname=empathy
pkgver=3.25.90+34+g78f4d4fda
pkgrel=3.nonprism1
pkgdesc="A GNOME instant messaging client using the Telepathy framework, without geoclue2 support"
url="https://wiki.gnome.org/Apps/Empathy"
arch=(x86_64 i686 armv7h)
license=(GPL2)
depends=(clutter-gst clutter-gtk folks gcr iso-codes libcanberra libpulse webkit2gtk
telepathy-farstream telepathy-glib telepathy-logger telepathy-mission-control
geocode-glib cheese libchamplain libgudev)
makedepends=(intltool itstool docbook-xsl python gnome-common git)
optdepends=('telepathy-gabble: XMPP/Jabber support'
'telepathy-idle: IRC support'
'telepathy-salut: Link-local XMPP support'
'telepathy-haze: libpurple support')
_commit=78f4d4fdadd7da67e063c2905649f6a6015ef8f9 # master
source=("git+https://git.gnome.org/browse/empathy#commit=$_commit"
"git+https://git.gnome.org/browse/telepathy-account-widgets"
enchant-2.patch)
sha256sums=('SKIP'
'SKIP'
'f177f0dfc242018dd52e312637f513fd08f64aa991b45930cc3ea9a2576f795e')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^EMPATHY_//;s/_/./g;s/-/+/g'
}
prepare() {
cd $pkgname
git submodule init
git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
git submodule update
patch -Np1 -i ../enchant-2.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
export LANG=en_US.UTF-8 LC_ALL=en_US.UTF-8
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/empathy \
--disable-static \
--disable-Werror \
--enable-location=no
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
