blob: 208f439e00aa5700327dfef3b0c7383494690659 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 159771 2016-02-01 07:51:10Z bgyorgy $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Christian Himpel <chressie at gmail dot com>
# Contributor (Arch): Johannes Hanika <hanatos at gmail dot com>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=darktable
pkgver=2.1.0
pkgrel=2.nonprism1
pkgdesc="Utility to organize and develop raw images, without flickcurl support"
arch=('i686' 'x86_64')
url=http://darktable.sf.net/
license=('GPL3')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('exiv2>=0.18' 'lcms2' 'lensfun>=0.2.3' 'desktop-file-utils'
'curl' 'libsecret' 'libgphoto2' 'openexr' 'sqlite' 'libxslt'
'libsoup' 'gtk3' 'pugixml' 'osm-gps-map' 'json-glib' 'lua52'
'colord' 'colord-gtk' 'graphicsmagick')
makedepends=('intltool>=0.40' 'cmake' 'librsvg')
optdepends=('librsvg')
install=darktable.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/darktable-org/darktable/archive/release-$pkgver.tar.gz")
md5sums=('d53daedd850447c9d4f61ed6022c3b74')
build() {
cd "$srcdir/$pkgname-release-$pkgver"
mkdir -p build
cd build
CXXFLAGS+=" -fpermissive"
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DBINARY_PACKAGE_BUILD=1 \
-DBUILD_USERMANUAL=False \
-DUSE_LIBSECRET=On \
-DUSE_LUA=On \
-DUSE_GNOME_KEYRING=Off \
-DUSE_COLORD=On \
-DPROJECT_VERSION=$pkgver \
-DUSE_USE_FLICKR=Off \
..
make
cd ../tools/basecurve
cmake .
make
}
package() {
cd "$srcdir/$pkgname-release-$pkgver/build"
make DESTDIR="$pkgdir" install
install -Dm0755 ../tools/basecurve/dt-curve-tool $pkgdir/usr/bin/dt-curve-tool
install -Dm0755 ../tools/basecurve/dt-curve-tool-helper $pkgdir/usr/bin/dt-curve-tool-helper
}
|
