blob: ea788571bbd6e9f13684eb9fc5c42bb6f42de417 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer (Arch): Martin Poehlmann <mpdeimos@outlook.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=california
pkgver=0.4.0
pkgrel=2.10.nonprism1
pkgdesc='A new calendar application for GNOME 3. It is currently under heavy development, without Google Calendar support'
arch=('i686' 'x86_64' 'armv7h')
url="https://wiki.gnome.org/Apps/California"
license=('LGPL2.1')
depends=('evolution-data-server' 'libgee' 'xdg-utils' "libical>=3" "libical<4")
depends_x86_64=("icu>=61" "icu<62")
depends_i686=("icu>=60" "icu<61")
depends_armv7h=("icu>=61" "icu<62")
makedepends=('vala' 'intltool' 'gnome-common' 'yelp-tools' 'gobject-introspection' 'patch')
install="${pkgname}.install"
source=('https://download.gnome.org/sources/california/0.4/california-0.4.0.tar.xz'
'0002-Build-with-evolution-data-server-3.13.90.patch'
'california-0.4.0-libical-3.0.patch'
'nonprism.patch')
sha256sums=('b25f356363a9f8f8f93c7ab78af02de39f9c3b71964663129ac9904de9147eb6'
'f512f50470954ec4018c99c49c37fa7e23074653a2e090ff13e32631ec10293d'
'c6924c868d2b44639463ce7e426c5917377ec7d0d6aa0fd38f7a018a9563be33'
'31bb9d156017c308d5ab18e515b1310db8f890a1defee8d0ee6a5ac3cb65a76e')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "$srcdir/0002-Build-with-evolution-data-server-3.13.90.patch"
patch -Np1 -i "$srcdir/california-0.4.0-libical-3.0.patch"
# remove Google Calendar support
patch -Np1 -i "$srcdir/nonprism.patch"
rm -rv src/activator/google
cd po
for file in *.po; do
intltool-update ${file%.*}
msgattrib --no-obsolete -o $file $file
done
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--disable-fatal
sed -i 's#californiadocdir = ${prefix}#californiadocdir = ${datadir}#g' Makefile
sed -i 's/static const/const/' src/host/host-main-window.vala
sed -i 's/static const/const/' src/application/california-application.vala
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make install DESTDIR="$pkgdir"
install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
}
|
