blob: 1caacfb0a1373bbaf9eae6e92f271a0a5b03779b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id$
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# parabola changes and rationale:
# removed nonfree asm files
pkgname=xscreensaver
_pkgname=$pkgname-libre
pkgver=5.40
pkgrel=1.parabola1
pkgdesc="Screen saver and locker for the X Window System, without nonfree asm files"
arch=('x86_64' 'i686' 'armv7h')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libglade' 'libxmu' 'glu' 'xorg-appres' 'perl-libwww')
makedepends=('bc' 'intltool' 'libxpm' 'gdm')
optdepends=('gdm: for login manager support')
backup=('etc/pam.d/xscreensaver')
mksource=(http://www.jwz.org/xscreensaver/${pkgname}-${pkgver}.tar.gz)
source=(https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz
LICENSE)
mksha256sums=('30a0908d4164cf780ef034f87ba884316296b308af2484261ccde86be0c95ae0')
sha256sums=('823e34a303a807d3e08ce1de9b7bf0291f6a327bf254627aea86488c9682876e'
'c0247a0328f07656f6b7a5854f57fe735579f161b6f40df967cf9a5eab772d63')
mksource() {
cd ${pkgname}-${pkgver}
# Deleting dmsc.asm file due which don't have source code supplied
rm -v hacks/images/m6502/dmsc.asm
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
--with-pam --with-login-manager --with-gtk --with-gl \
--without-gle --with-pixbuf --with-jpeg
make
}
package() {
cd ${pkgname}-${pkgver}
install -d "${pkgdir}/etc/pam.d"
make install_prefix="${pkgdir}" install
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
chmod 755 "${pkgdir}/usr/bin/xscreensaver"
echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}
|
