blob: 140ea8af4a70394873e30a97e836d6353118412f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# $Id: PKGBUILD 212497 2017-02-15 05:21:07Z bgyorgy $
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Alexander Fehr <pizzapunk gmail com>
# Contributor (Arch): Andrew Simmons <andrew.simmons@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@parabola.nu>
pkgbase=xarchiver
pkgname=(xarchiver xarchiver-gtk2)
pkgver=0.5.4.11
_gitrev=79a73d46b782cf8bb93d058d00d2cb81a9b3df8a
pkgrel=1.parabola1
pkgdesc="GTK+ frontend to various command line archivers, without nonfree unrar support"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/ib/xarchiver"
license=('GPL')
depends=('gtk2' 'gtk3')
makedepends=('docbook-xsl' 'intltool' 'xmlto')
optdepends=('zip: ZIP support'
'unzip: ZIP support'
'p7zip: 7z support'
'lzop: LZOP support'
'cpio: RPM support'
'unar: RAR support')
source=($pkgbase-$pkgver.tar.gz::https://github.com/ib/xarchiver/archive/$_gitrev.tar.gz
libre.patch)
sha256sums=('2dabd6f5d96c5d886d9a5ed7d299cfc43d1fef88be37d1d298a78c4c01a63b45'
'a0ca78f2e7c6a95cc09e7a3483aed1923850e219316b123bb80f33a63d274386')
prepare() {
cd $pkgbase-$_gitrev
# Remove nonfree unRAR support
patch -p1 -i ../libre.patch
./autogen.sh
}
build() {
# GTK+ 3 version
[ -d gtk3 ] || cp -r $pkgbase-$_gitrev gtk3
cd gtk3
./configure --prefix=/usr --libexecdir=/usr/lib/xfce4
make -j1
cd "$srcdir"
# GTK+ 2 version
[ -d gtk2 ] || cp -r $pkgbase-$_gitrev gtk2
cd gtk2
./configure --prefix=/usr --libexecdir=/usr/lib/xfce4 --enable-gtk2
make -j1
}
package_xarchiver() {
depends=('gtk3')
conflicts=('xarchiver-libre')
replaces=('xarchiver-libre')
cd gtk3
make DESTDIR="$pkgdir" install
}
package_xarchiver-gtk2() {
pkgdesc+=' (GTK+ 2 version)'
depends=('gtk2')
conflicts=('xarchiver')
cd gtk2
make DESTDIR="$pkgdir" install
}
|
