1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
|
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor (Arch): Thomas Dziedzic <gostrc@gmail.com>
# Contributor (Arch): Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor (Arch): tobias [ tobias at archlinux org ]
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Christian Hesse <mail@eworm.de>
# Contributor (Arch): Eli Schwartz
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# parabola changes and rationale:
# rebranded to parabola
pkgbase=vim
pkgname=('vim' 'gvim' 'vim-runtime')
pkgver=8.0.1436
_versiondir=80
pkgrel=1.parabola1
url='http://www.vim.org'
arch=('x86_64' 'i686' 'armv7h')
license=('custom:vim')
makedepends=('glibc' 'libgcrypt' 'gpm' 'python2' 'python' 'ruby' 'libxt' 'gtk3' 'lua'
'gawk' 'tcl' 'pcre' 'zlib' 'libffi')
source=(vim-${pkgver}.tar.gz::https://github.com/vim/vim/archive/v${pkgver}.tar.gz
vimrc
parabola.vim
vimdoc.hook)
sha256sums=('5e56ba39e7156ec8516f0c5a35721dec69517cedf246c5d25258ff94c57368fb'
'6c22ef5791004dc3a1151400a3ce6aec35f660237aed734bcde0a8a16882cbc0'
'b84bae636f763ab6706d911eb03853416378608079b82d0d809fc71a49ba0781'
'7095cafac21df7aa42749d6864d1c0549fe65771d8edda3102c931c60782b6b9')
sha512sums=('fcbd5aa68f0f94baa2645265a7eb8dc705876930afffc312e3bec00c4c7543abb1017e8b4c68afed85d5fea625634a9dad305ee553814afc840b3352d8c35995'
'33608b0551c0829d802fe8f710a2e0381fd9cf013b2321ebf3cbda36ce973d115139bf4dbbe19ce79f1df85f4ca5f571347269c561ecf3a70a22ddc9c42043f2'
'7d200149e28f91e0fc8ac62d3821529629d59e4e3ea6a785a5f6061099c3337bc5076d180b71933117f2ad775295b17ef94a949a9c076c053b3a639164bf0316'
'1e06e981691b17662fd0fddac5c00c87c920d1b4a1cbb6191c42d57cc40b00af12710e26b22fcfc0901bb8142b15f6a04aa65cec2d9b3bb9d5a06cb650d3ab9c')
prepare() {
(cd vim-${pkgver}/src
# define the place for the global (g)vimrc file (set to /etc/vimrc)
sed -i 's|^.*\(#define SYS_.*VIMRC_FILE.*"\) .*$|\1|' feature.h
sed -i 's|^.*\(#define VIMRC_FILE.*"\) .*$|\1|' feature.h
autoconf
)
cp -a vim-${pkgver} gvim-${pkgver}
}
build() {
msg2 "Building vim..."
(cd vim-${pkgver}
./configure \
--prefix=/usr \
--localstatedir=/var/lib/vim \
--with-features=huge \
--with-compiledby='Parabola GNU/Linux-libre' \
--enable-gpm \
--enable-acl \
--with-x=no \
--disable-gui \
--enable-multibyte \
--enable-cscope \
--enable-netbeans \
--enable-perlinterp=dynamic \
--enable-pythoninterp=dynamic \
--enable-python3interp=dynamic \
--enable-rubyinterp=dynamic \
--enable-luainterp=dynamic \
--enable-tclinterp=dynamic
make
)
msg2 "Building gvim..."
(cd gvim-${pkgver}
./configure \
--prefix=/usr \
--localstatedir=/var/lib/vim \
--with-features=huge \
--with-compiledby='Parabola GNU/Linux-libre' \
--enable-gpm \
--enable-acl \
--with-x=yes \
--enable-gui=gtk3 \
--enable-multibyte \
--enable-cscope \
--enable-netbeans \
--enable-perlinterp=dynamic \
--enable-pythoninterp=dynamic \
--enable-python3interp=dynamic \
--enable-rubyinterp=dynamic \
--enable-luainterp=dynamic \
--enable-tclinterp=dynamic
make
)
}
check() {
cd vim-${pkgver}
TERM=xterm make -j1 test
}
package_vim-runtime() {
pkgdesc='Runtime for vim and gvim (Parabola rebranded)'
backup=('etc/vimrc')
cd vim-${pkgver}
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# man and bin files belong to 'vim'
rm -r "${pkgdir}"/usr/share/man/ "${pkgdir}"/usr/bin/
# Don't forget logtalk.dict
install -Dm 644 runtime/ftplugin/logtalk.dict \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/ftplugin/logtalk.dict
# fix FS#17216
sed -i 's|messages,/var|messages,/var/log/messages.log,/var|' \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/filetype.vim
# patch filetype.vim for better handling of pacman related files
sed -i "s/rpmsave/pacsave/;s/rpmnew/pacnew/;s/,\*\.ebuild/\0,PKGBUILD*,*.install/" \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/filetype.vim
sed -i "/find the end/,+3{s/changelog_date_entry_search/changelog_date_end_entry_search/}" \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/ftplugin/changelog.vim
# rc files
install -Dm 644 "${srcdir}"/vimrc "${pkgdir}"/etc/vimrc
install -Dm 644 "${srcdir}"/parabola.vim \
"${pkgdir}"/usr/share/vim/vimfiles/parabola.vim
# rgb.txt file
install -Dm 644 runtime/rgb.txt \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/rgb.txt
# no desktop files and icons
rm -r "${pkgdir}"/usr/share/{applications,icons}
# license
install -dm 755 "${pkgdir}"/usr/share/licenses/vim-runtime
ln -s /usr/share/vim/vim${_versiondir}/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/vim-runtime/license.txt
# pacman hook for documentation helptags
install -Dm 644 "${srcdir}"/vimdoc.hook "${pkgdir}"/usr/share/libalpm/hooks/vimdoc.hook
}
package_vim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'acl' 'glibc' 'libgcrypt' 'pcre'
'zlib' 'libffi')
optdepends=('python2: Python 2 language support'
'python: Python 3 language support'
'ruby: Ruby language support'
'lua: Lua language support'
'perl: Perl language support'
'tcl: Tcl language support')
conflicts=('gvim' 'vim-minimal' 'vim-python3')
provides=('xxd' 'vim-minimal' 'vim-python3')
replaces=('vim-python3' 'vim-minimal')
cd vim-${pkgver}
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# provided by (n)vi in core
rm "${pkgdir}"/usr/bin/{ex,view}
# delete some manpages
find "${pkgdir}"/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd "${_mandir}"
rm -f ex.1 view.1 # provided by (n)vi
rm -f evim.1 # this does not make sense if we have no GUI
done
# Runtime provided by runtime package
rm -r "${pkgdir}"/usr/share/vim
# no desktop files and icons
rm -r "${pkgdir}"/usr/share/{applications,icons}
# license
install -Dm 644 runtime/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/${pkgname}/license.txt
}
package_gvim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor (with advanced features, such as a GUI)'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'libxt' 'gtk3' 'glibc' 'libgcrypt' 'pcre'
'zlib' 'libffi')
optdepends=('python2: Python 2 language support'
'python: Python 3 language support'
'ruby: Ruby language support'
'lua: Lua language support'
'perl: Perl language support'
'tcl: Tcl language support')
provides=("vim=${pkgver}-${pkgrel}" "xxd")
conflicts=('vim-minimal' 'vim')
replaces=('gvim-python3')
cd gvim-${pkgver}
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# provided by (n)vi in core
rm "${pkgdir}"/usr/bin/{ex,view}
# delete some manpages
find "${pkgdir}"/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd "${_mandir}"
rm -f ex.1 view.1 # provided by (n)vi
done
# need to remove since this is provided by vim-runtime
rm -r "${pkgdir}"/usr/share/vim
# keep gvim desktop file only, remove vim
rm "${pkgdir}"/usr/share/applications/vim.desktop
# license
install -Dm 644 runtime/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/${pkgname}/license.txt
}
|
