1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
|
# $Id: PKGBUILD 262456 2016-03-23 18:48:23Z anatolik $
# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor (Arch): Thomas Dziedzic <gostrc@gmail.com>
# Contributor (Arch): Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor (Arch): tobias [ tobias at archlinux org ]
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgbase=vim
pkgname=(vim gvim vim-runtime)
pkgver=7.4.1639
_versiondir=74
pkgrel=1.parabola1
arch=(i686 x86_64)
license=('custom:vim')
url='http://www.vim.org'
makedepends=(gpm python2 python ruby libxt desktop-file-utils gtk2 gtk3 lua gawk tcl)
source=(vim-$pkgver.tar.gz::http://github.com/vim/vim/archive/v$pkgver.tar.gz
vimrc
parabola.vim)
sha1sums=('b116ce38e00b6d93e1f76bdcda52f93f3e8dee6c'
'7bacf26cb66f6c36184a62bc306ef33bfe892686'
'a72ca0f8d941ff221598091338d9c1bf75a3494b')
prepare() {
cd vim-$pkgver/src
# define the place for the global (g)vimrc file (set to /etc/vimrc)
sed -i 's|^.*\(#define SYS_.*VIMRC_FILE.*"\) .*$|\1|' feature.h
sed -i 's|^.*\(#define VIMRC_FILE.*"\) .*$|\1|' feature.h
autoconf
cd "$srcdir"
cp -a vim-$pkgver gvim-$pkgver
}
build() {
cd "${srcdir}"/vim-$pkgver
./configure \
--prefix=/usr \
--localstatedir=/var/lib/vim \
--with-features=huge \
--with-compiledby='Parabola GNU/Linux-libre' \
--enable-gpm \
--enable-acl \
--with-x=no \
--disable-gui \
--enable-multibyte \
--enable-cscope \
--enable-netbeans \
--enable-perlinterp=dynamic \
--enable-pythoninterp=dynamic \
--enable-python3interp=dynamic \
--enable-rubyinterp=dynamic \
--enable-luainterp=dynamic \
--enable-tclinterp=dynamic
make
cd "${srcdir}"/gvim-$pkgver
./configure \
--prefix=/usr \
--localstatedir=/var/lib/vim \
--with-features=huge \
--with-compiledby='Parabola GNU/Linux-libre' \
--enable-gpm \
--enable-acl \
--with-x=yes \
--enable-gui=gtk2 \
--enable-multibyte \
--enable-cscope \
--enable-netbeans \
--enable-perlinterp=dynamic \
--enable-pythoninterp=dynamic \
--enable-python3interp=dynamic \
--enable-rubyinterp=dynamic \
--enable-luainterp=dynamic \
--enable-tclinterp=dynamic
make
}
check() {
# disable tests because they seem to freeze
cd "${srcdir}"/vim-$pkgver
#make test
cd "${srcdir}"/gvim-$pkgver
#make test
}
package_vim-runtime() {
pkgdesc='Runtime for vim and gvim (Parabola rebranded)'
backup=('etc/vimrc')
replaces=(${pkgname}-parabola)
conflicts=(${pkgname}-parabola)
cd "${srcdir}"/vim-$pkgver
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# man and bin files belong to 'vim'
rm -r "${pkgdir}"/usr/share/man/ "${pkgdir}"/usr/bin/
# Don't forget logtalk.dict
install -Dm644 runtime/ftplugin/logtalk.dict \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/ftplugin/logtalk.dict
# fix FS#17216
sed -i 's|messages,/var|messages,/var/log/messages.log,/var|' \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/filetype.vim
# patch filetype.vim for better handling of pacman related files
sed -i "s/rpmsave/pacsave/;s/rpmnew/pacnew/;s/,\*\.ebuild/\0,PKGBUILD*,*.install/" \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/filetype.vim
sed -i "/find the end/,+3{s/changelog_date_entry_search/changelog_date_end_entry_search/}" \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/ftplugin/changelog.vim
# rc files
install -Dm644 "${srcdir}"/vimrc "${pkgdir}"/etc/vimrc
install -Dm644 "${srcdir}"/parabola.vim \
"${pkgdir}"/usr/share/vim/vimfiles/parabola.vim
# rgb.txt file
install -Dm644 runtime/rgb.txt \
"${pkgdir}"/usr/share/vim/vim${_versiondir}/rgb.txt
# license
install -dm755 "${pkgdir}"/usr/share/licenses/vim-runtime
ln -s /usr/share/vim/vim${_versiondir}/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/vim-runtime/license.txt
}
package_vim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor (with support for additional scripting languages)'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'acl')
optdepends=('python2: Python 2 language support'
'python: Python 3 language support'
'ruby: Ruby language support'
'lua: Lua language support'
'perl: Perl language support'
'tcl: Tcl language support')
conflicts=('gvim' 'vim-minimal' 'vim-python3')
provides=('xxd' 'vim-minimal' 'vim-python3')
replaces=('vim-python3' 'vim-minimal')
cd "${srcdir}"/vim-$pkgver
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# provided by (n)vi in core
rm "${pkgdir}"/usr/bin/{ex,view}
# delete some manpages
find "${pkgdir}"/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd ${_mandir}
rm -f ex.1 view.1 # provided by (n)vi
rm -f evim.1 # this does not make sense if we have no GUI
done
# Runtime provided by runtime package
rm -r "${pkgdir}"/usr/share/vim
# license
install -Dm644 runtime/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/${pkgname}/license.txt
}
package_gvim() {
pkgdesc='Vi Improved, a highly configurable, improved version of the vi text editor (with advanced features, such as a GUI)'
depends=("vim-runtime=${pkgver}-${pkgrel}" 'gpm' 'libxt' 'desktop-file-utils' 'gtk2')
optdepends=('python2: Python 2 language support'
'python: Python 3 language support'
'ruby: Ruby language support'
'lua: Lua language support'
'perl: Perl language support'
'tcl: Tcl language support')
provides=("vim=${pkgver}-${pkgrel}" "xxd")
conflicts=('vim-minimal' 'vim')
replaces=('gvim-python3')
install=gvim.install
cd "${srcdir}"/gvim-$pkgver
make -j1 VIMRCLOC=/etc DESTDIR="${pkgdir}" install
# provided by (n)vi in core
rm "${pkgdir}"/usr/bin/{ex,view}
# delete some manpages
find "${pkgdir}"/usr/share/man -type d -name 'man1' 2>/dev/null | \
while read _mandir; do
cd ${_mandir}
rm -f ex.1 view.1 # provided by (n)vi
done
# need to remove since this is provided by vim-runtime
rm -r "${pkgdir}"/usr/share/vim
# freedesktop links
install -Dm644 runtime/gvim.desktop "${pkgdir}"/usr/share/applications/gvim.desktop
install -Dm644 runtime/vim48x48.png "${pkgdir}"/usr/share/pixmaps/gvim.png
# license
install -Dm644 runtime/doc/uganda.txt \
"${pkgdir}"/usr/share/licenses/${pkgname}/license.txt
}
|
