blob: 8e4e9a818db4ea426b4a573bf0a50ca9845e329a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor (Arch): Cedric Girard <girard.cedric@gmail.com>
# Contributor (Arch): N30N <archlinux@alunamation.com>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
pkgname=unar
pkgver=1.10.1
_commit=1534a5cf6900
pkgrel=9
pkgdesc="unar and lsar: Objective-C tools for uncompressing archive files"
arch=(x86_64)
arch+=(i686 armv7h)
url="http://unarchiver.c3.cx/"
license=('LGPL2.1')
depends=(gnustep-base openssl bzip2 icu gcc-libs zlib)
depends+=('icu>=62' 'icu<63')
makedepends=(gcc-objc gnustep-make)
replaces=(unarchiver unrar)
conflicts=(unarchiver unrar)
provides=(unarchiver unrar)
source=("https://bitbucket.org/kosovan/theunarchiver/get/unar-${pkgver}.tar.gz"
"native_obj_exceptions.patch")
sha1sums=('d7dac2b1786e63787dbea74030ecdf8c425de730'
'b8024026607dc2de758479b73d8b01ca6f692b59')
prepare(){
cd "$srcdir/kosovan-theunarchiver-${_commit}"
patch -p1 < ../native_obj_exceptions.patch
}
build() {
cd "$srcdir/kosovan-theunarchiver-${_commit}/XADMaster"
. /usr/share/GNUstep/Makefiles/GNUstep.sh
make -f Makefile.linux
}
package() {
cd "$srcdir/kosovan-theunarchiver-${_commit}/XADMaster"
install -d "$pkgdir/usr/bin/"
install -m755 unar lsar "$pkgdir/usr/bin/"
cd "$srcdir/kosovan-theunarchiver-${_commit}/Extra"
install -d "$pkgdir/usr/share/man/man1"
install -m644 lsar.1 unar.1 "$pkgdir/usr/share/man/man1/"
install -d "$pkgdir/usr/share/bash-completion/completions/"
install -m644 unar.bash_completion "$pkgdir/usr/share/bash-completion/completions/unar"
install -m644 lsar.bash_completion "$pkgdir/usr/share/bash-completion/completions/lsar"
}
|
