blob: 95427fa8814ffe9501f6c9c07d4fe364a5cd52ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# U-Boot: BeagleBoard and BeagleBoard-xM
# Maintainer (Arch): Kevin Mihelich <kevin@archlinuxarm.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
buildarch=4
_pkgname=linux-libre-lts
pkgname=uboot-beagleboard-${_pkgname}
pkgver=2015.04
pkgrel=1
pkgdesc="U-Boot for BeagleBoard and BeagleBoard-xM (built for the linux-libre-lts kernel package)"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
depends=('linux-libre-lts')
makedepends=('bc')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
'0001-parabola-arm-modifications.patch'
'uEnv.txt')
md5sums=('570bdc2c47270c2a98ca60ff6c5c74cd'
'98d94d7e1ac1302da57c89dc3b5b9f5b'
'd41d8cd98f00b204e9800998ecf8427e')
prepare() {
cd u-boot-${pkgver}
patch -Np1 -i ../0001-parabola-arm-modifications.patch
}
build() {
cd u-boot-${pkgver}
unset LDFLAGS CFLAGS CXXFLAGS
make distclean
make omap3_beagle_config
make
}
package() {
cd u-boot-${pkgver}
mkdir -p "${pkgdir}/boot/${pkgname}"
cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}/boot/${pkgname}"
}
|
