blob: c915f1b4ce67c96d45b38cf615e732f2f45b4c73 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: xduugu
# Contributor: nh2
# Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor: Nick B <Shirakawasuna ð gmail đ com>
# Contributor: Christof Musik <christof ð senfdax đ de>
# Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>
pkgname=tp_smapi-libre-lts
_pkgname=tp_smapi
_extramodules=/usr/lib/modules/extramodules-3.10-LIBRE-LTS
pkgver=0.41
pkgrel=13
pkgdesc="Modules for ThinkPad's SMAPI functionality (built for the linux-libre-lts kernel package)"
arch=('i686' 'x86_64' 'mips64el')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
depends=('linux-libre-lts>=3.10' 'linux-libre-lts<3.11')
makedepends=('linux-libre-lts-headers>=3.10' 'linux-libre-lts-headers<3.11')
replaces=('tp_smapi-lts')
conflicts=('tp_smapi-lts')
provides=("tp_smapi-lts=${pkgver}")
install='tp_smapi-lts.install'
source=("https://github.com/downloads/evgeni/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
md5sums=('63c683415c764568f6bf17c7eabe4752')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
_kernver=$(< "${_extramodules}/version")
sed -ri -e "s/^(KVER\s*:=).*$/\1 ${_kernver}/" \
-e "s#^(KBASE\s*:=).*\$#\1 ${_extramodules%/*}/${_kernver}#" Makefile
make HDAPS=1
}
package() {
_kernver=$(< "${_extramodules}/version")
make -C "${_extramodules%/*}/${_kernver}/build" \
INSTALL_MOD_PATH="${pkgdir}/${_extramodules%%/lib/*}" \
M="${srcdir}/${_pkgname}-${pkgver}" modules_install
cd "${pkgdir}/${_extramodules%/*}"
mv "${_kernver}/extra" "${_extramodules##*/}"
rmdir "${_kernver}"
# compress kernel modules
find "${pkgdir}" -name "*.ko" -exec gzip -9 {} +
# load module on startup
echo tp_smapi > "${srcdir}/tp_smapi-lts.conf"
install -Dm644 "${srcdir}/tp_smapi-lts.conf" "${pkgdir}/usr/lib/modules-load.d/tp_smapi-lts.conf"
# update kernel version in install file
sed -ri "s#^(extramodules=).*\$#\1${_extramodules}#" "${startdir}/tp_smapi-lts.install"
}
|
