blob: 1d5c6a6a79c949146750bd19af613c947b34cec4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
pkgname=smplayer
pkgver=17.10.0
pkgrel=1.parabola1
pkgdesc='Media player with built-in codecs that can play virtually all video and audio formats, without nonfree smtube support'
url='http://www.smplayer.info/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('qt5-script' 'mpv' 'hicolor-icon-theme' 'libx11' 'zlib' 'gcc-libs')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
'smplayer-skins: skin themes collection'
'youtube-dl: youtube videos and streaming'
'mplayer: alternative multimedia engine')
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2
disable-smtube-support.patch
add-missing-QClipboard-include.patch)
sha256sums=('3d40a999343c647cc758a8d5026be9d355dcc84317700128578e51db9f982375'
'e86a0881d6696dfe2b5a2742947f317090194beab4986df7e9ac8845727e78de'
'abb66acd70e61bc2bf7abfa2887b24b76004e00b9649a9b38aa44b4409fea08e')
prepare() {
cd $pkgname-$pkgver
# disable SMTube support
patch -p1 -i $srcdir/disable-smtube-support.patch
# add missing QClipboard include
patch -p1 -i $srcdir/add-missing-QClipboard-include.patch
# fix GNU/Linux name
sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
}
build() {
cd $pkgname-$pkgver
make PREFIX=/usr \
DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}
package() {
cd $pkgname-$pkgver
make DOC_PATH=/usr/share/doc/smplayer \
DESTDIR="$pkgdir" PREFIX=/usr install
}
# vim: ts=2 sw=2 et:
|
