blob: 9084a653e0c1a55fdde9fbcb6cbfb579cb86b016 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Maintainer: David P. <megver83@parabola.nu>
_target=sh-elf
pkgname=$_target-gcc
_pkgver=8.1.0
pkgver=$_pkgver+20180427
_islver=0.19
pkgrel=1
_snapshot=${pkgver:0:1}-${pkgver##$_pkgver+}
pkgdesc="The GNU Compiler Collection - cross compiler for SuperH target"
arch=('x86_64' 'i686' 'armv7h')
url='http://gcc.gnu.org/'
license=(GPL LGPL FDL)
depends=($_target-binutils libmpc zlib)
makedepends=(gmp mpfr $_target-newlib)
optdepends=("$_target-newlib: Standard C library ($_target target)")
options=(!emptydirs !strip)
source=(#https://gcc.gnu.org/pub/gcc/releases/gcc-$_pkgver/gcc-$_pkgver.tar.bz2
https://gcc.gnu.org/pub/gcc/snapshots/$_snapshot/gcc-$_snapshot.tar.xz
http://isl.gforge.inria.fr/isl-$_islver.tar.bz2)
sha512sums=('c38c382f2246e2164d5f8d0402c4cfad7de0084f0d63d2ef9b489b7fa1695b157a2983f282811b6089dcb447432866d80dae4e84561c7f41395558cd96901d67'
'08f4db964d9e02ec8aa9779378ed76e0ddf1d56f81f87664dbf787555ce496cdc87e836f8a51ae137f45e648c604870cce07ee45919eafb549e404afb8f27083')
if [ -n "$_snapshot" ]; then
_basedir=gcc-$_snapshot
else
_basedir=gcc-$_pkgver
fi
prepare() {
cd $_basedir
# link isl for in-tree builds
ln -sf ../isl-$_islver isl
echo $_pkgver > gcc/BASE-VER
# hack! - some configure tests for header files using "$CPP $CPPFLAGS"
sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" "$srcdir"/$_basedir/{libiberty,gcc}/configure
mkdir $srcdir/build-gcc
}
build() {
cd build-gcc
# using -pipe causes spurious test-suite failures
# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=48565
CFLAGS=${CFLAGS/-pipe/}
CXXFLAGS=${CXXFLAGS/-pipe/}
$srcdir/$_basedir/configure \
--target=$_target \
--prefix=/usr \
--libexecdir=/usr/lib \
--with-sysroot=/usr/$_target \
--with-native-system-header-dir=/include \
--enable-languages=c,c++ \
--enable-plugins \
--enable-shared \
--disable-decimal-float \
--disable-libffi \
--disable-libgomp \
--disable-libmudflap \
--disable-libquadmath \
--disable-libssp \
--disable-libstdcxx-pch \
--disable-nls \
--disable-threads \
--disable-tls \
--with-gnu-as \
--with-gnu-ld \
--with-system-zlib \
--with-newlib \
--with-python-dir=share/gcc-$_target \
--with-gmp \
--with-mpfr \
--with-mpc \
--with-isl \
--with-libelf \
--enable-gnu-indirect-function \
--with-pkgversion='Parabola Repository' \
--with-bugurl='https://labs.parabola.nu/'
make $MAKEFLAGS
}
package() {
cd build-gcc
make DESTDIR="$pkgdir" install
# strip target binaries
find "$pkgdir"/usr/lib/gcc/$_target/$_pkgver "$pkgdir"/usr/$_target/lib -type f -and \( -name \*.a -or -name \*.o \) -exec $_target-objcopy -R .comment -R .note -R .debug_info -R .debug_aranges -R .debug_pubnames -R .debug_pubtypes -R .debug_abbrev -R .debug_line -R .debug_str -R .debug_ranges -R .debug_loc '{}' \;
# strip host binaries
find "$pkgdir"/usr/bin/ "$pkgdir"/usr/lib/gcc/$_target/$_pkgver -type f -and \( -executable \) -exec strip '{}' \;
# Remove files that conflict with host gcc package
rm -r "$pkgdir"/usr/share/man/man7
rm -r "$pkgdir"/usr/share/info
rm "$pkgdir"/usr/lib/libcc1.*
}
|
