blob: a176d8c1c6cb13b0c451d0f76fd524cb4ba68ca9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 257681 2016-01-09 09:49:01Z arojas $
# Maintainer (Arch): Daniel Isenmann <daniel@archlinux.org>
# Contributor (Arch): orelien <aurelien.foret@wanadoo.fr>
# Maintainer: André Silva <emulatorman@hyperbola.info>
pkgname=rp-pppoe
pkgver=3.12
pkgrel=1.parabola1
pkgdesc="Roaring Penguin's Point-to-Point Protocol over Ethernet client, without nonfree ServPoET recommendation"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.roaringpenguin.com/pppoe/"
license=('GPL')
depends=('ppp=2.4.7' 'sh' 'net-tools')
backup=(etc/ppp/pppoe.conf etc/ppp/firewall-standalone etc/ppp/firewall-masq
etc/ppp/pppoe-server-options)
options=('!makeflags')
replaces=('rp-pppoe-libre')
conflicts=('rp-pppoe-libre')
install=rp-pppoe.install
source=(http://www.roaringpenguin.com/files/download/rp-pppoe-$pkgver.tar.gz{,.sig}
adsl.service
kmode.patch
libre.patch)
validpgpkeys=('FC2E9B645468698FD7B21655C1842E2A126F42E0') # Dianne Skoll
prepare() {
cd "$srcdir/$pkgname-$pkgver"
## remove nonfree software recommendation (ServPoET)
rm -v SERVPOET
patch -Np1 -i "$srcdir/libre.patch"
cd "$srcdir/$pkgname-$pkgver/src"
patch -Np2 -i ../../kmode.patch
}
build() {
cd "$srcdir/$pkgname-$pkgver/src"
./configure --prefix=/usr --sbindir=/usr/bin --enable-plugin
make PLUGIN_DIR="/usr/lib/rp-pppoe" all rp-pppoe.so
}
package() {
cd "$srcdir/$pkgname-$pkgver/src"
make PLUGIN_DIR="/usr/lib/rp-pppoe" DESTDIR="$pkgdir" install
#install -Dm755 "$srcdir/adsl" "$pkgdir/etc/rc.d/adsl"
install -Dm644 "$srcdir/adsl.service" "$pkgdir/usr/lib/systemd/system/adsl.service"
}
md5sums=('216eb52b69062b92a64ee37fd71f4b66'
'SKIP'
'926b00aa2a0c0d3a21970acde9695e47'
'8df35e67558b6b4567d1ab24c9202898'
'40586f5bc2729d3a56b2fe1aa6bb683a')
|
