blob: 33c84cd5230504ba02f3864659b50fd6fe692ed1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# $Id: PKGBUILD 215716 2017-03-11 19:59:39Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): Themaister <maister@archlinux.us>
# Contributor (Arch): lifning <definelightning@gmail.com>
# Maintainer: André Silva <emulatorman@hyperbola.info>
pkgname=retroarch
pkgver=1.5.0
pkgrel=2.parabola1
pkgdesc='Reference frontend for the libretro API, without nonfree software support, libretro-genesis-plus and libretro-snes9x recommendation'
arch=('i686' 'x86_64' 'armv7h')
url='http://www.libretro.com/'
license=('GPL')
groups=('libretro')
depends=('alsa-lib' 'gcc-libs' 'glibc' 'libdrm' 'libgl' 'libpulse' 'libusb'
'libx11' 'libxcb' 'libxext' 'libxinerama' 'libxkbcommon' 'libxv'
'libxxf86vm' 'mesa' 'openal' 'sdl2' 'wayland' 'zlib'
'libass.so' 'libavcodec.so' 'libavformat.so' 'libavutil.so'
'libfreetype.so' 'libswresample.so' 'libswscale.so' 'libudev.so')
makedepends=('vulkan-icd-loader')
optdepends=('libretro-desmume: Nintendo DS core'
'libretro-gambatte: Nintendo Game Boy/Game Boy Color core'
'libretro-mgba: Nintendo Game Boy Advance core'
'libretro-mupen64plus: Nintendo 64 core'
'libretro-nestopia: Nintendo Entertainment System core'
'libretro-pcsx-rearmed: Sony PlayStation core'
'libretro-reicast: Sega Dreamcast core'
'libretro-yabause: Sega Saturn core'
'libretro-overlays: Collection of overlays'
'libretro-shaders: Collection of shaders'
'retroarch-assets-xmb: XMB menu assets'
'retroarch-autoconfig-udev: udev joypad autoconfig')
backup=('etc/retroarch.cfg')
source=("retroarch-${pkgver}.tar.gz::https://github.com/libretro/RetroArch/archive/v${pkgver}.tar.gz"
'libre.patch')
sha256sums=('5de6385d4a0031709ef133d04a8573309e1090f0fda2917678be8e1147576de5'
'47a7d20d92cd9aa7d845465fd1b056f98f95fd93c4e001158a1e9ffd48dc872c')
prepare() {
cd RetroArch-${pkgver}
patch -p1 -i ${srcdir}/libre.patch
}
build() {
cd RetroArch-${pkgver}
./configure \
--prefix='/usr' \
--disable-cg \
--disable-jack \
--disable-oss \
--disable-sdl
make
make -C gfx/video_filters
}
package() {
cd RetroArch-${pkgver}
make DESTDIR="${pkgdir}" install
install -dm 755 "${pkgdir}"/usr/lib/retroarch/filters/video
install -m 644 gfx/video_filters/*.{filt,so} "${pkgdir}"/usr/lib/retroarch/filters/video/
}
# vim: ts=2 sw=2 et:
|
