blob: 4293cb6299b2e89ec2b3f2f939ed9e9b9881ee69 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Contributor (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): Dan Vratil <progdan@progdansoft.com>
# Contributor (Arch): thotypous <matiasΘarchlinux-br·org>
# Contributor (Arch): delor <bartekpiech gmail com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# parabola changes and rationale:
# - removed support for qt5-webengine
# - added patch to build on arm
pkgname=qtcreator
pkgver=4.6.2
_clangver=6.0.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Lightweight, cross-platform integrated development environment'
pkgdesc+=', without nonfree qt5-webengine support'
arch=(x86_64)
arch+=(i686 armv7h)
url='http://qt-project.org'
license=(LGPL)
depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 clang=$_clangver qbs)
makedepends=(git mesa llvm)
options=(docs)
optdepends=('qt5-doc: integrated Qt documentation'
'qt5-examples: welcome page examples'
'qt5-translations: for other languages'
'gdb: debugger'
'cmake: cmake project support'
'x11-ssh-askpass: ssh support'
'git: git support'
'mercurial: mercurial support'
'bzr: bazaar support'
'valgrind: analyze support')
source=("http://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz")
source+=('0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch'
'libre.patch')
sha256sums=('bbaf667f51051c602df02e04c1d7369bef9553326d8377bc36a019ae718843cc'
'56e6876f41ee8909ee197f7ab5a2bb18ad5a7fe26ce490a48cdf062fa199ffc6'
'53d119a70047c6b64d8227e65d402d308017cc1d99d8886421bf2da4f7407c80')
prepare() {
mkdir -p build
# fix hardcoded libexec path
sed -e 's|libexec\/qtcreator|lib\/qtcreator|g' -i qt-creator-opensource-src-${pkgver}/qtcreator.pri
# use system qbs
rm -r qt-creator-opensource-src-${pkgver}/src/shared/qbs
# remove qt5-webengine support
cd qt-creator-opensource-src-${pkgver}
patch -Np1 -i "$srcdir"/libre.patch
rm -rv src/plugins/help/webenginehelpviewer.{cpp,h}
# fix arm build
if [[ "$CARCH" == arm* ]]; then
git apply ../0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch
fi
}
build() {
cd build
qmake LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr CONFIG+=journald QMAKE_CFLAGS_ISYSTEM=-I \
DEFINES+=QBS_ENABLE_PROJECT_FILE_UPDATES "$srcdir"/qt-creator-opensource-src-${pkgver}/qtcreator.pro
make
make docs
}
package() {
cd build
make INSTALL_ROOT="$pkgdir/usr/" install
make INSTALL_ROOT="$pkgdir/usr/" install_docs
install -Dm644 "$srcdir"/qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
}
|
