blob: be1c9d6f33df6c2d55b0b6e16e2c943ed2a211fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
pkgbase=parabola-hackers
pkgname=(parabola-hackers parabola-hackers-nshd)
pkgver=20170908
pkgdesc='Programs for doing magic with hackers.git'
url='https://git.parabola.nu/packages/parabola-hackers.git/'
license=('GPL')
pkgrel=1
arch=('x86_64' 'i686')
makedepends=('go')
source=("https://repo.parabola.nu/other/$pkgbase/$pkgbase-$pkgver.tar.gz"{,.sig})
sha256sums=('3d074623fd570d0ee5cbe3662b9eb9d2095211314b5bc097a4d6855f0cddfa80'
'SKIP')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker
build() {
cd "$srcdir/$pkgbase-$pkgver"
printf '%s\n' \
prefix='/usr' \
bindir='$(libexecdir)/$(PACKAGE)' \
libexecdir='$(libdir)' \
sysconfdir='/etc' \
>> config.mk
make
}
check() {
cd "$srcdir/$pkgbase-$pkgver"
make check
}
package_parabola-hackers() {
backup=(etc/$pkgbase.yml)
depends=('ruby' 'colordiff')
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="${pkgdir}" install
find "$pkgdir" -type f \( -name 'nshd*' -o -name shadow \) -delete
find "$pkgdir" -type d -empty -exec rmdir -p --ignore-fail-on-non-empty -- {} +
}
package_parabola-hackers-nshd() {
pkgdesc='NSS and PAM integration for parabola-hackers'
license=('GPL3')
depends=("parabola-hackers=$pkgver" 'nss-pam-ldapd')
backup=(etc/nshd/shadow)
install=parabola-hackers-nshd.install
replaces=(nshd)
conflicts=(nshd)
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="${pkgdir}" install
find "$pkgdir" -type f -not \( -name 'nshd*' -o -name shadow \) -delete
find "$pkgdir" -type d -empty -exec rmdir -p --ignore-fail-on-non-empty -- {} +
install -d "${pkgdir}/usr/share/licenses/${pkgname}"
cp -t "${pkgdir}/usr/share/licenses/${pkgname}" -- LICENSE.txt LICENSE.bsd*.txt
}
|
