blob: 7619db1318bfd0e7189f22cf8d3edeb9fd76ac98 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer (Arch): Evangelos Foutras <evangelos@foutrelis.com>
# Contributor (Arch): Gaetan Bisson <bisson@archlinux.org>
# Contributor (Arch): Thayer Williams <thayer@archlinux.org>
# Contributor (Arch): Hugo Doria <hugo@archlinux.org>
# Contributor (Arch): TuxSpirit<tuxspirit@archlinux.fr>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_pkgname=p7zip-libre
pkgname=p7zip
pkgver=17.04
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Command-line file archiver with high compression ratio"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://github.com/jinfeihan57/p7zip"
license=('LGPL')
conflicts=('p7zip-libre')
replaces=('p7zip-libre')
depends=('gcc-libs' 'sh')
source=(https://github.com/jinfeihan57/p7zip/archive/v$pkgver/$pkgname-v$pkgver.tar.gz
oemcp-iconv.patch::https://github.com/jinfeihan57/p7zip/commit/c104127e6a93.patch
oemcp-cygwin.patch::https://github.com/jinfeihan57/p7zip/commit/0e0a1a8316b6.patch
oemcp-apple.patch::https://github.com/jinfeihan57/p7zip/commit/334a01e3f8bc.patch
libre.patch)
sha256sums=('ea029a2e21d2d6ad0a156f6679bd66836204aa78148a4c5e498fe682e77127ef'
'e32636aa03b9c75a2b9d9138e03a738ceed6ca5da4c3c67e7f5981e135fb9e24'
'fa658d42cc1da2b567a210a819502bd8e3bb1e02d5d23e087e2278c4aaffe15e'
'a1b21ceb5582633d85d41ec9e4995f758cba1731dd80fb6f45a7bc6b18bfe394'
'5dd8986cbc8541b9197235163d1bc63cc04956bf8256a5473f9682dfdf6843c1')
prepare() {
cd $pkgname-$pkgver
# Remove nonfree unRAR utility files from the source
rm -rv CPP/7zip/{Archive,Compress}/Rar
rm -v CPP/7zip/Compress/{Rar{1,2,3}Decoder.{cpp,h},Rar3Vm.{cpp,h},RarCodecsRegister.cpp}
rm -v CPP/7zip/Crypto/{Rar20Crypto,Rar{,5}Aes}.{cpp,h}
rm -v Utils/file_Codecs_Rar_so.py
rm -v DOC/unRarLicense.txt
# Remove nonfree parent folder icon
rm CPP/7zip/UI/FileManager/res/ParentFolder.h
# Remove RAR and parent folder icon references
patch -Np1 -i ../libre.patch
# https://github.com/jinfeihan57/p7zip/issues/112
patch -Rp1 -i ../oemcp-apple.patch
patch -Rp1 -i ../oemcp-cygwin.patch
patch -Rp1 -i ../oemcp-iconv.patch
}
build() {
cd $pkgname-$pkgver
make OPTFLAGS="$CPPFLAGS $CFLAGS" 7z 7zr 7za
}
package() {
cd $pkgname-$pkgver
make install \
DEST_DIR="$pkgdir" \
DEST_HOME=/usr \
DEST_MAN=/usr/share/man
# Remove documentation for the GUI file manager
rm -r "$pkgdir/usr/share/doc/p7zip/DOC/MANUAL/fm"
install -d "${pkgdir}"/usr/share/licenses/p7zip
ln -s -t "$pkgdir/usr/share/licenses/p7zip/" \
/usr/share/doc/p7zip/DOC/License.txt
chmod -R a+r,u+w,a+X "$pkgdir/usr"
}
# vim:set ts=2 sw=2 et:
|
