blob: 56bdeae1003b70977fdd162083ee311df7ca19bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer (Arch): Vesa Kaihlavirta <vegai@iki.fi>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# parabola changes and rationale:
# - removed recommendation for non-free openttd-opensfx
pkgname=openttd
pkgver=1.9.2
pkgrel=1
pkgrel+=.par1
pkgdesc='An engine for running Transport Tycoon Deluxe.'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://www.openttd.org'
license=('GPL')
depends=('libpng' 'sdl' 'icu' 'fontconfig' 'lzo' 'hicolor-icon-theme' 'desktop-file-utils' 'xz' 'fluidsynth')
optdepends=('openttd-opengfx: free graphics')
source=("https://proxy.binaries.openttd.org/openttd-releases/${pkgver}/${pkgname}-${pkgver}-source.tar.xz")
sha256sums=('f9ff8c255145a1dd617798a9413179cc740a0cc91709455990880a15eeb7564a')
build() {
cd ${pkgname}-${pkgver}
# http://site.icu-project.org/download/61#TOC-Migration-Issues
CXXFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
./configure \
--prefix-dir=/usr \
--binary-name=${pkgname} \
--binary-dir=bin \
--data-dir=share/${pkgname} \
--install-dir="${pkgdir}" \
--doc-dir=share/doc/${pkgname} \
--with-fluidsynth \
--menu-name="OpenTTD"
make
}
package() {
local _icu_ver
_icu_ver=$(pacman -S --print-format='%v' icu)
depends+=("icu>=${_icu_ver}" "icu<$((${_icu_ver%%.*} + 1))")
cd ${pkgname}-${pkgver}
make install
}
|
