1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=openexr
_pkgname=$pkgname-libre
pkgver=2.3.0
pkgrel=1
pkgrel+=.par2
pkgdesc="An high dynamic-range image file format library"
pkgdesc+=", without embedded nonfree fonts in the documentation"
url="https://www.openexr.com/"
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('BSD3')
depends=('zlib' 'ilmbase')
makedepends=('unoconv' 'libepoxy')
replaces=("$_pkgname")
conflicts=("$_pkgname")
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('2382fb28c34289a9ad6a9e7666a50a89e8848980609e96a9b4b37c6b97b00a67')
mksource=("https://github.com/openexr/openexr/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz"
"https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/InterpretingDeepPixels.docx"
"https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/MultiViewOpenEXR.odt"
"https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/OpenEXRFileLayout.odt"
"https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/ReadingAndWritingImageFiles.odt"
"https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/TechnicalIntroduction.odt")
mksha256sums=('fd6cb3a87f8c1a233be17b94c74799e6241d50fc5efd4df75c7a4b9cf4e25ea6'
'208147fafb904114e7afa5f632d583be741db765fd341e6ad21b8455a2175436'
'38c46075f7efe02e231d32753966ffa463f2a3c4673dd8ea71dd47560c403db0'
'20880ea9223606f3721d2fad7f0efdd7dfd7f1e7966bbaddd5aa68dc70c16766'
'a4fdf678244f6c37e5ae126a9385a2e154b824b67e1746ed10bc17907c6b45ba'
'fab77bb2afb3d580387249807300fa26c70eaf46ca23a0036165bafee607dc4e')
noextract=(InterpretingDeepPixels.docx MultiViewOpenEXR.odt OpenEXRFileLayout.odt ReadingAndWritingImageFiles.odt TechnicalIntroduction.odt)
mksource() {
cd "${pkgname}-${pkgver}"
# remove documentation with embedded nonfree fonts
rm -rv "doc/"{InterpretingDeepPixels,MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction,TheoryDeepPixels}.pdf
# add source documentation
install -m644 -v "${srcdir}/"{InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt} doc
# convert source documentation to pdf format and clean source code
cd doc
unoconv -v -f pdf {InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt}
echo "acaboo"
rm -rv "${srcdir}/"{_rels,Configurations2,customXml,docProps,META-INF,ObjBFFFDCA{1,3,4,5,7},Object\ 1,ObjectReplacements,Pictures,Thumbnails,word}
}
prepare() {
# remove TheoryDeepPixels.pdf reference
sed -i '\|TheoryDeepPixels[.]pdf|d
\|InterpretingDeepPixels[.]pdf| s| [\]||
' "${srcdir}/${pkgname}-${pkgver}/doc/Makefile."{am,in}
}
build() {
cd "${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}
package() {
cd "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 "doc/"{InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt} "${pkgdir}/usr/share/doc/${pkgname}"
}
|
