blob: f1a4fb1af310910d317ac2843185a30ecf18f26d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
# $Id: PKGBUILD 282836 2016-12-05 09:59:13Z lcarlier $
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgbase=opencv
pkgname=opencv
pkgver=3.1.0
pkgrel=6.parabola1
pkgdesc="Free Computer Vision Library, without nonfree SIFT and SURF algorithms, nonfree Milky icons and lena images"
arch=('i686' 'x86_64' 'armv7h')
license=('BSD')
url="http://opencv.org/"
depends=('intel-tbb' 'openexr' 'xine-lib' 'libdc1394' 'gtkglext')
makedepends=('cmake' 'python-numpy' 'python2-numpy' 'mesa' 'eigen')
optdepends=('opencv-samples'
'eigen'
'opencl-icd-loader: For coding with OpenCL'
'python-numpy: Python 3 interface'
'python2-numpy: Python 2 interface')
mksource=("$pkgbase-$pkgver.zip::https://github.com/Itseez/opencv/archive/$pkgver.zip"
"opencv_contrib-$pkgver.tar.gz::https://github.com/Itseez/opencv_contrib/archive/$pkgver.tar.gz")
source=("https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.zip"
"opencv-gcc6.patch::https://github.com/mshabunin/opencv/commit/a0fdc91a.patch" '5852.patch')
mkmd5sums=('6082ee2124d4066581a7386972bfd52a'
'a822839ad3ab79ff837c16785ea9dd10')
md5sums=('5e3c409fa9f1beeda5ba5edfcf02a921'
'4dacea7866d28014939a652f268cc7c1'
'5bd9cd736b171c15cedee3a32a0c47ff')
_cmakeopts=('-D WITH_OPENCL=ON'
'-D WITH_OPENGL=ON'
'-D WITH_TBB=ON'
'-D WITH_XINE=ON'
'-D WITH_GSTREAMER=OFF'
'-D BUILD_WITH_DEBUG_INFO=OFF'
'-D BUILD_TESTS=OFF'
'-D BUILD_PERF_TESTS=OFF'
'-D BUILD_EXAMPLES=ON'
'-D INSTALL_C_EXAMPLES=ON'
'-D INSTALL_PYTHON_EXAMPLES=ON'
'-D CMAKE_BUILD_TYPE=Release'
'-D CMAKE_INSTALL_PREFIX=/usr'
'-D CMAKE_SKIP_RPATH=ON'
#'-D WITH_IPP=ON'
#'-D INSTALL_CREATE_DISTRIB=ON'
)
# SSE only available from Pentium 3 onwards (i686 is way older)
# SSE only available x86 hardware and ARM uses NEON
[[ "$CARCH" = 'i686' || "$CARCH" = 'armv7h' ]] && \
_cmakeopts+=('-D ENABLE_SSE=OFF'
'-D ENABLE_SSE2=OFF'
'-D ENABLE_SSE3=OFF')
mksource() {
cd "$srcdir/opencv_contrib-$pkgver"
# remove nonfree SIFT and SURF algorithms that are patented in some countries and have some other limitations on the use
rm -v modules/xfeatures2d/src/{sift,surf}.cpp
cd "$srcdir/$pkgname-$pkgver"
# remove nonfree Milky icons
rm -rv modules/highgui/src/files_Qt/Milky
# remove nonfree lena.png and lena.jpg images
rm -v $(find . -iname '*lena*')
}
prepare() {
cd "$srcdir/opencv_contrib-$pkgver"
# remove nonfree SIFT and SURF references
rm -rv modules/xfeatures2d
cd "$srcdir/$pkgname-$pkgver"
patch -p1 -i "$srcdir/5852.patch"
# fix build with GCC 6
patch -p1 -i "$srcdir/opencv-gcc6.patch"
}
build() {
cd "$srcdir/$pkgname-$pkgver"
cmake ${_cmakeopts[@]} \
-DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
.
make
}
package_opencv() {
options=('staticlibs')
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
# install license file
install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
cd "$pkgdir/usr/share"
# separate samples package; also be -R friendly
if [[ -d OpenCV/samples ]]; then
rm -r OpenCV/samples
mv OpenCV $pkgname # otherwise folder naming is inconsistent
elif [[ ! -d OpenCV ]]; then
warning "Directory naming issue; samples package may not be built!"
fi
}
# vim:set ts=2 sw=2 et:
|
