blob: 221542d5f20d504bca0c32af26aea0d88d6a0886 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# $Id: PKGBUILD 287727 2017-01-29 17:55:00Z arojas $
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgbase=opencv
pkgname=opencv
pkgver=3.3.1
pkgrel=1.parabola1
pkgdesc="Free Computer Vision Library, without nonfree SIFT and SURF algorithms, nonfree Milky icons and lena images"
arch=('i686' 'x86_64' 'armv7h')
license=('BSD')
url="http://opencv.org/"
depends=('intel-tbb' 'openexr' 'xine-lib' 'libdc1394' 'gtkglext')
makedepends=('cmake' 'python-numpy' 'python2-numpy' 'mesa' 'eigen' 'hdf5')
optdepends=('opencv-samples'
'hdf5: support for HDF5 format'
'opencl-icd-loader: For coding with OpenCL'
'python-numpy: Python 3 interface'
'python2-numpy: Python 2 interface')
mksource=("$pkgbase-$pkgver.zip::https://github.com/opencv/opencv/archive/$pkgver.zip"
"opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz")
source=("https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.zip")
mksha256sums=('e59412c7e0d398113b1e454d600fcdff54cd77100a84483ac0d82bbf52496932'
'6f3ce148dc6e147496f0dbec1c99e917e13bf138f5a8ccfc3765f5c2372bd331')
sha256sums=('9bf24efc68c82d211fdaff7ed9b007b1a49353d7e092658b51285d4a1d7f3b56')
_cmakeopts=('-D WITH_OPENCL=ON'
'-D WITH_OPENGL=ON'
'-D WITH_TBB=ON'
'-D WITH_XINE=ON'
'-D WITH_GSTREAMER=OFF'
'-D BUILD_WITH_DEBUG_INFO=OFF'
'-D BUILD_TESTS=OFF'
'-D BUILD_PERF_TESTS=OFF'
'-D BUILD_EXAMPLES=ON'
'-D INSTALL_C_EXAMPLES=ON'
'-D INSTALL_PYTHON_EXAMPLES=ON'
'-D CMAKE_BUILD_TYPE=Release'
'-D CMAKE_INSTALL_PREFIX=/usr'
'-D CMAKE_SKIP_RPATH=ON'
'-D WITH_IPP=OFF'
#'-D INSTALL_CREATE_DISTRIB=ON'
)
# SSE only available from Pentium 3 onwards (i686 is way older)
# SSE only available x86 hardware and ARM uses NEON
[[ "$CARCH" = 'i686' || "$CARCH" = 'armv7h' ]] && \
_cmakeopts+=('-D ENABLE_SSE=OFF'
'-D ENABLE_SSE2=OFF'
'-D ENABLE_SSE3=OFF')
mksource() {
cd "$srcdir/opencv_contrib-$pkgver"
# remove nonfree SIFT and SURF algorithms that are patented in some countries and have some other limitations on the use
rm -v modules/xfeatures2d/src/{sift,surf}.cpp
cd "$srcdir/$pkgname-$pkgver"
# remove nonfree Milky icons
rm -rv modules/highgui/src/files_Qt/Milky
# remove nonfree lena.png and lena.jpg images
rm -v $(find . -iname '*lena*')
}
prepare() {
cd "$srcdir/opencv_contrib-$pkgver"
# remove nonfree SIFT and SURF references
rm -rv modules/xfeatures2d
}
build() {
mkdir -p build
cd build
cmake ${_cmakeopts[@]} \
-DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
../$pkgname-$pkgver
make
}
package_opencv() {
options=('staticlibs')
cd build
make DESTDIR="$pkgdir" install
# install license file
install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
cd "$pkgdir/usr/share"
# separate samples package; also be -R friendly
if [[ -d OpenCV/samples ]]; then
rm -r OpenCV/samples
mv OpenCV $pkgname # otherwise folder naming is inconsistent
elif [[ ! -d OpenCV ]]; then
warning "Directory naming issue; samples package may not be built!"
fi
}
# vim:set ts=2 sw=2 et:
|
