blob: ed29b527318a7e3c897cbe25ec2dcea3e25cbca2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): grimsock <lord.grimsock at gmail dot com>
# Contributor (Arch): Alessandro Sagratini <ale_sagra at hotmail dot com>
# Contributor (Arch): Arkham <arkham at archlinux dot us>
# Contributor (Arch): LeCrayonVert < greenarrow at archlinux dot us>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=nikto
pkgver=2.1.6
pkgrel=1.parabola1
pkgdesc='A web server scanner which performs comprehensive tests against web servers for multiple items, without nonfree databases'
url='https://github.com/sullo/nikto'
arch=('any')
license=('GPL')
depends=('sh' 'openssl' 'perl-net-ssleay' 'perl-json')
backup=('etc/nikto.conf')
mksource=(${pkgname}-${pkgver}.tar.gz::https://github.com/sullo/${pkgname}/archive/${pkgver}.tar.gz)
source=(https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.tar.xz
nikto.sh)
mksha512sums=('13632018ef6862de7dc53c674d7266fcfb7e164bcf3070327c103cbf8737720ffb710ccc8949acc920a6e0a85da1bb7575d073ee245bc2ba3a8a292ad1695e69')
sha512sums=('93dbf03a74b40f6ec0cedacf798b73129cadeec35f34cd6d70fbdc14973175a1638f4333a234806c1ef27855f4d44526eebb56f27e524f1f17548b6148669d7d'
'75b9be1f1cacbca09a5e72f8125aadc24938a3ac36b2337bf68916231af52e2af846a0dedb36782f45716d2c6d590a3606cb5879339528e7a744f1d2d880120d')
mksource(){
cd "${pkgname}-${pkgver}"
# Remove nonfree databases
rm -rv $(grep -rlI 'not be used with any software product')
}
prepare() {
cd ${pkgname}-${pkgver}
find . -type f ! -name nikto.pl -exec chmod 644 {} +
}
package() {
cd ${pkgname}-${pkgver}
install -d "${pkgdir}/usr/share/nikto"
cp -a program/* "${pkgdir}/usr/share/nikto"
install -Dm 755 "${srcdir}/nikto.sh" "${pkgdir}/usr/bin/nikto"
install -Dm 644 program/nikto.conf "${pkgdir}/etc/nikto.conf"
install -Dm 644 documentation/nikto.1 "${pkgdir}/usr/share/man/man1/nikto.1"
install -Dm 644 program/docs/nikto_manual.html "${pkgdir}/usr/share/doc/${pkgname}/manual.html"
install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README"
}
# vim: ts=2 sw=2 et:
|
