blob: 2f1028119644d642577bca15e55eafb5e9b70576 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id: PKGBUILD 32760 2010-11-18 03:40:37Z foutrelis $
# Maintainer (Parabola): fauno <fauno@kiwwwi.com.ar>
# Maintainer: Evangelos Foutras <foutrelis@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
pkgname=mplayer-vaapi-libre
pkgver=33025
_vaapi_version=20110127
pkgrel=3
pkgdesc="A movie player, compiled with vaapi support, without faac dependency, added speex support"
arch=('i686' 'x86_64')
url="http://www.splitted-desktop.com/~gbeauchesne/mplayer-vaapi/"
license=('GPL')
depends=('libxxf86dga' 'libxxf86vm' 'libmad' 'cdparanoia' 'libxinerama' 'sdl'
'lame' 'libtheora' 'xvidcore' 'libmng' 'libxss' 'libgl' 'smbclient'
'aalib' 'jack' 'libcaca' 'x264' 'lirc-utils' 'ttf-dejavu' 'speex'
'libxvmc' 'enca' 'opencore-amr' 'libdca' 'a52dec' 'schroedinger'
'libvpx' 'libpulse' 'fribidi' 'libva' 'desktop-file-utils')
makedepends=('unzip' 'mesa' 'live-media>=2010.01.13' 'yasm')
provides=("mplayer-vaapi=$pkgver")
conflicts=('mplayer' 'mplayer-vaapi')
replaces=("mplayer-vaapi=$pkgver")
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
source=(http://pkgbuild.com/~foutrelis/mplayer-$pkgver.tar.xz
http://www.splitted-desktop.com/~gbeauchesne/mplayer-vaapi/mplayer-vaapi-$_vaapi_version.tar.bz2
mplayer.desktop
mplayer.png
patch-fixes.patch)
install=mplayer-vaapi.install
md5sums=('3814e5c47458de4bf0878d3996820341'
'b39bd73ae8241dcb21dd1a8fa5eb87eb'
'647b9f4ab5284a7fef3f84f992214e77'
'd00874ccc644b7f43d6ef1c942fcef28'
'9f96a03dddbea8be5ff2fa3925311d04')
build() {
cd "$srcdir/mplayer-$pkgver"
# Custom CFLAGS break the mplayer build
unset CFLAGS LDFLAGS
# Update vaapi patches for changes introduced in mplayer/ffmpeg
patch -d "$srcdir/mplayer-vaapi-$_vaapi_version" -p1 -i \
"$srcdir/patch-fixes.patch"
for patch in mplayer-{vaapi{,-{gma500-workaround,0.29}},vdpau}; do
patch -Np1 -i "$srcdir/mplayer-vaapi-$_vaapi_version/patches/$patch.patch"
done
./configure --prefix=/usr \
--disable-faac \
--enable-runtime-cpudetection \
--disable-gui \
--disable-arts \
--disable-liblzo \
--enable-speex \
--disable-openal \
--disable-libdv \
--disable-musepack \
--disable-esd \
--disable-mga \
--enable-xvmc \
--disable-vdpau \
--enable-vaapi \
--language=all \
--confdir=/etc/mplayer
[ "$CARCH" = "i686" ] && sed 's|-march=i486|-march=i686|g' -i config.mak
make
make -j1 DESTDIR=$pkgdir install
install -Dm644 etc/{codecs.conf,input.conf,example.conf} "$pkgdir/etc/mplayer/"
install -dm755 "$pkgdir/usr/share/mplayer/"
ln -s /usr/share/fonts/TTF/DejaVuSans.ttf "$pkgdir/usr/share/mplayer/subfont.ttf"
rm -rf "$pkgdir/usr/share/mplayer/font"
# Desktop file (FS#14770)
install -Dm644 "$srcdir/mplayer.desktop" "$pkgdir/usr/share/applications/mplayer.desktop"
install -Dm644 "$srcdir/mplayer.png" "$pkgdir/usr/share/pixmaps/mplayer.png"
}
# vim:set ts=2 sw=2 et:
|
