blob: 35054754db30f5d518e6bb299739f07e987b2dd6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# $Id: PKGBUILD 204039 2014-01-14 12:09:50Z jgc $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Márcio Silva <coadde@parabola.nu>
_pkgbase=mplayer
pkgbase=mplayer-libre
pkgname=('mplayer-libre' 'mencoder-libre')
pkgver=36498
pkgrel=5
arch=('i686' 'x86_64')
makedepends=(
'libxxf86dga' 'libxxf86vm' 'libmad' 'libxinerama' 'sdl' 'lame' 'libtheora'
'xvidcore' 'libmng' 'libxss' 'libgl' 'smbclient' 'aalib' 'jack' 'libcaca'
'x264' 'faad2' 'lirc-utils' 'libxvmc' 'enca' 'libvdpau' 'opencore-amr'
'libdca' 'a52dec' 'schroedinger' 'libvpx' 'libpulse' 'fribidi' 'unzip' 'mesa'
'live-media' 'yasm' 'git' 'fontconfig' 'mpg123' 'ladspa' 'libass' 'libbluray'
'libcdio-paranoia' 'opus'
)
license=('GPL')
url='http://www.mplayerhq.hu/'
options=('!buildflags' '!emptydirs')
source=(ftp://ftp.archlinux.org/other/packages/$_pkgbase/$_pkgbase-$pkgver.tar.xz
http://ffmpeg.org/releases/ffmpeg-2.1.tar.bz2
mplayer.desktop
cdio-includes.patch
include-samba-4.0.patch)
md5sums=('8b856e8833d910b6e38b04bb8453d0dc'
'4ec1cedd4c7753512462f70b347c338a'
'62f44a58f072b2b1a3c3d3e4976d64b3'
'7b5be7191aafbea64218dc4916343bbc'
'868a92bdef148df7f38bfa992b26ce9d')
prepare() {
cd $_pkgbase-$pkgver
patch -p0 -i ../cdio-includes.patch
patch -p1 -i ../include-samba-4.0.patch
mv ../ffmpeg-2.1 ./ffmpeg
}
build() {
cd $_pkgbase-$pkgver
./configure --prefix=/usr \
--enable-runtime-cpudetection \
--disable-gui \
--disable-arts \
--disable-liblzo \
--disable-speex \
--disable-openal \
--disable-libdv \
--disable-musepack \
--disable-esd \
--disable-mga \
--disable-ass-internal \
--disable-cdparanoia \
--enable-xvmc \
--enable-radio \
--enable-radio-capture \
--enable-smb \
--language=all \
--confdir=/etc/mplayer
[[ "$CARCH" = "i686" ]] && sed 's|-march=i486|-march=i686|g' -i config.mak
make
}
package_mplayer-libre() {
pkgdesc="A movie player for GNU/Linux, without nonfree faac support"
install=mplayer.install
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
depends=(
'desktop-file-utils' 'ttf-font' 'enca' 'libxss' 'a52dec' 'libvpx'
'lirc-utils' 'x264' 'libmng' 'libdca' 'aalib' 'lame' 'fontconfig'
'libgl' 'libxinerama' 'libvdpau' 'libpulse' 'smbclient' 'xvidcore'
'opencore-amr' 'jack' 'libmad' 'sdl' 'libtheora' 'libcaca' 'libxxf86dga'
'fribidi' 'libjpeg' 'faad2' 'libxvmc' 'schroedinger' 'mpg123'
'libass' 'libxxf86vm' 'libbluray' 'libcdio-paranoia' 'opus'
)
provides=("mplayer=$pkgver")
replaces=('mplayer')
conflicts=('mplayer')
cd $_pkgbase-$pkgver
make DESTDIR="$pkgdir" install-mplayer install-mplayer-man
install -Dm644 etc/{codecs.conf,input.conf,example.conf} \
"$pkgdir/etc/mplayer/"
# desktop file FS#14770
install -Dm644 "$srcdir/mplayer.desktop" \
"$pkgdir/usr/share/applications/mplayer.desktop"
install -Dm644 etc/mplayer256x256.png \
"$pkgdir/usr/share/pixmaps/mplayer.png"
}
package_mencoder-libre() {
pkgdesc="Free command line video decoding, encoding and filtering tool, without nonfree faac support"
depends=(
'enca' 'a52dec' 'libvpx' 'x264' 'libmng' 'libdca' 'bzip2' 'lame'
'alsa-lib' 'fontconfig' 'giflib' 'libpng' 'smbclient' 'xvidcore'
'opencore-amr' 'libmad' 'libtheora' 'fribidi' 'libjpeg' 'faad2'
'schroedinger' 'mpg123' 'libass' 'libbluray' 'libcdio-paranoia'
'libvorbis' 'opus'
)
provides=("mencoder=$pkgver")
replaces=('mencoder')
conflicts=('mencoder')
cd $_pkgbase-$pkgver
make DESTDIR="$pkgdir" install-mencoder install-mencoder-man
find "$pkgdir/usr/share/man" -name mplayer.1 -exec rename mplayer.1 mencoder.1 {} +
}
|
