1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
|
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgbase=mesa
pkgname=('opencl-mesa' 'libva-mesa-driver' 'mesa-vdpau' 'mesa'
'mesa-libgl' 'mesa-libcl-icd' 'vulkan-radeon')
[[ "${CARCH}" = 'x86_64' || "${CARCH}" = 'i686' ]] && pkgname+=('vulkan-intel')
pkgver=17.0.1
pkgrel=2.parabola1
arch=('i686' 'x86_64' 'armv7h')
makedepends=('python2-mako' 'libxml2' 'libx11' 'glproto' 'libdrm' 'dri2proto' 'dri3proto' 'presentproto'
'libxshmfence' 'libxxf86vm' 'libxdamage' 'libvdpau' 'libva' 'wayland' 'elfutils' 'llvm'
'libomxil-bellagio' 'libclc' 'clang' 'lm_sensors')
url="http://mesa3d.sourceforge.net"
license=('custom')
source=(https://mesa.freedesktop.org/archive/mesa-${pkgver}.tar.xz{,.sig}
LICENSE
remove-libpthread-stubs.patch
0001-Fix-linkage-against-shared-glapi.patch
0001-glapi-Link-with-glapi-when-built-shared.patch
drirc)
sha256sums=('96fd70ef5f31d276a17e424e7e1bb79447ccbbe822b56844213ef932e7ad1b0c'
'SKIP'
'7fdc119cf53c8ca65396ea73f6d10af641ba41ea1dd2bd44a824726e01c8b3f2'
'75ab53ad44b95204c788a2988e97a5cb963bdbf6072a5466949a2afb79821c8f'
'c68d1522f9bce4ce31c92aa7a688da49f13043f5bb2254795b76dea8f47130b7'
'064dcd5a3ab1b7c23383e2cafbd37859e4c353f8839671d9695c6f7c2ef3260b'
'2cc6f40076e07a2d4769557c1aa40e5b6fbbb59c38e551c1a1997ef0d3f3c5f2')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>
prepare() {
cd ${srcdir}/mesa-${pkgver}
# Now mesa checks for libpthread-stubs - so remove the check
patch -Np1 -i ../remove-libpthread-stubs.patch
# non-upstreamed ones
patch -Np1 -i ../0001-Fix-linkage-against-shared-glapi.patch
patch -Np1 -i ../0001-glapi-Link-with-glapi-when-built-shared.patch
autoreconf -fiv
}
build() {
# copy source to build mesa-libcl-icd package
cp -a ${srcdir}/{mesa,opencl}-${pkgver}
cd ${srcdir}/mesa-${pkgver}
# softpipe,llvmpipe
if [[ "${CARCH}" = 'x86_64' || "${CARCH}" = 'i686' ]]; then
DRI=i915,i965,r200,radeon,nouveau,swrast
GALLIUM=r300,r600,radeonsi,nouveau,svga,swrast,virgl,swr
VULKAN=intel,radeon
elif [[ "${CARCH}" = 'armv7h' ]]; then
DRI=r200,radeon,nouveau,swrast
GALLIUM=freedreno,etnaviv,vc4,imx,r300,r600,radeonsi,nouveau,svga,swrast,virgl
VULKAN=radeon
fi
./configure --prefix=/usr \
--sysconfdir=/etc \
--with-dri-driverdir=/usr/lib/xorg/modules/dri \
--with-gallium-drivers=${GALLIUM} \
--with-dri-drivers=${DRI} \
--with-egl-platforms=x11,drm,wayland \
--with-vulkan-drivers=${VULKAN} \
--disable-xvmc \
--enable-gallium-llvm \
--enable-llvm-shared-libs \
--enable-shared-glapi \
--disable-libglvnd \
--enable-egl \
--enable-glx \
--enable-glx-tls \
--enable-gles1 \
--enable-gles2 \
--enable-gbm \
--enable-dri \
--enable-gallium-osmesa \
--enable-texture-float \
--enable-xa \
--enable-vdpau \
--enable-omx \
--enable-nine \
--enable-opencl \
--enable-opencl-icd \
--enable-gallium-extra-hud \
--enable-lmsensors \
--with-clang-libdir=/usr/lib
make
# fake installation
mkdir $srcdir/fakeinstall
make DESTDIR=${srcdir}/fakeinstall install
# build mesa-libcl-icd
cd ${srcdir}/opencl-${pkgver}
./configure --prefix=/usr \
--sysconfdir=/etc \
--with-gallium-drivers=${GALLIUM} \
--with-dri-drivers=${DRI} \
--with-egl-platforms=x11,drm,wayland \
--with-vulkan-drivers=${VULKAN} \
--disable-xvmc \
--enable-gallium-llvm \
--enable-llvm-shared-libs \
--enable-shared-glapi \
--disable-libglvnd \
--enable-egl \
--enable-glx \
--enable-glx-tls \
--enable-gles1 \
--enable-gles2 \
--enable-gbm \
--enable-dri \
--enable-gallium-osmesa \
--enable-texture-float \
--enable-xa \
--enable-vdpau \
--enable-omx \
--enable-nine \
--enable-opencl \
--enable-gallium-extra-hud \
--enable-lmsensors \
--with-clang-libdir=/usr/lib
make
# fake mesa-libcl-icd installation
mkdir $srcdir/openclinstall
make DESTDIR=${srcdir}/openclinstall install
}
package_opencl-mesa() {
pkgdesc="OpenCL support for AMD/ATI Radeon mesa drivers"
depends=('expat' 'libdrm' 'libelf' 'libclc' 'clang' 'lm_sensors')
optdepends=('opencl-headers: headers necessary for OpenCL development')
provides=('opencl-driver')
install -m755 -d ${pkgdir}/etc
cp -rv ${srcdir}/fakeinstall/etc/OpenCL ${pkgdir}/etc/
install -m755 -d ${pkgdir}/usr/lib/gallium-pipe
cp -rv ${srcdir}/fakeinstall/usr/lib/libMesaOpenCL* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/gallium-pipe/pipe_{r600,radeonsi}.so ${pkgdir}/usr/lib/gallium-pipe/
install -m755 -d "${pkgdir}/usr/share/licenses/opencl-mesa"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/opencl-mesa/"
}
package_vulkan-intel() {
pkgdesc="Intel's Vulkan mesa driver"
depends=('wayland' 'libx11' 'libxshmfence')
provides=('vulkan-driver')
install -m755 -d ${pkgdir}/usr/share/vulkan/icd.d
cp -rv ${srcdir}/fakeinstall/usr/share/vulkan/icd.d/intel_icd*.json ${pkgdir}/usr/share/vulkan/icd.d/
install -m755 -d ${pkgdir}/usr/{include/vulkan,lib}
cp -rv ${srcdir}/fakeinstall/usr/lib/libvulkan_intel.so ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/include/vulkan/vulkan_intel.h ${pkgdir}/usr/include/vulkan
install -m755 -d "${pkgdir}/usr/share/licenses/vulkan-intel"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/vulkan-intel/"
}
package_vulkan-radeon() {
pkgdesc="Radeon's Vulkan mesa driver"
depends=('wayland' 'libx11' 'libxshmfence' 'libelf' 'libdrm' 'llvm-libs')
provides=('vulkan-driver')
install -m755 -d ${pkgdir}/usr/share/vulkan/icd.d
cp -rv ${srcdir}/fakeinstall/usr/share/vulkan/icd.d/radeon_icd*.json ${pkgdir}/usr/share/vulkan/icd.d/
install -m755 -d ${pkgdir}/usr/lib
cp -rv ${srcdir}/fakeinstall/usr/lib/libvulkan_radeon.so ${pkgdir}/usr/lib/
install -m755 -d "${pkgdir}/usr/share/licenses/vulkan-radeon"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/vulkan-radeon/"
}
package_libva-mesa-driver() {
pkgdesc="VA-API implementation for gallium"
depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'libelf' 'libxshmfence' 'lm_sensors')
install -m755 -d ${pkgdir}/usr/lib
cp -rv ${srcdir}/fakeinstall/usr/lib/dri ${pkgdir}/usr/lib
install -m755 -d "${pkgdir}/usr/share/licenses/libva-mesa-driver"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/libva-mesa-driver/"
}
package_mesa-vdpau() {
pkgdesc="Mesa VDPAU drivers"
depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'libelf' 'libxshmfence' 'lm_sensors')
install -m755 -d ${pkgdir}/usr/lib
cp -rv ${srcdir}/fakeinstall/usr/lib/vdpau ${pkgdir}/usr/lib
install -m755 -d "${pkgdir}/usr/share/licenses/mesa-vdpau"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-vdpau/"
}
package_mesa() {
pkgdesc="A free implementation of the OpenGL specification"
depends=('libdrm' 'wayland' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'libelf'
'libomxil-bellagio' 'libtxc_dxtn' 'llvm-libs' 'mesa-libgl' 'lm_sensors')
optdepends=('opengl-man-pages: for the OpenGL API man pages'
'mesa-vdpau: for accelerated video playback'
'libva-mesa-driver: for accelerated video playback')
if [[ "${CARCH}" = 'x86_64' || "${CARCH}" = 'i686' ]]; then
provides=('ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri' 'opengl-driver')
conflicts=('ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri')
replaces=('ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri')
elif [[ "${CARCH}" = 'armv7h' ]]; then
provides=('ati-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri' 'opengl-driver')
conflicts=('ati-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri')
replaces=('ati-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri')
fi
install -m755 -d ${pkgdir}/etc
cp -rv ${srcdir}/drirc ${pkgdir}/etc
install -m755 -d ${pkgdir}/usr/lib/xorg/modules/dri
# ati-dri, nouveau-dri, intel-dri, svga-dri, swrast
cp -av ${srcdir}/fakeinstall/usr/lib/xorg/modules/dri/* ${pkgdir}/usr/lib/xorg/modules/dri
cp -rv ${srcdir}/fakeinstall/usr/lib/bellagio ${pkgdir}/usr/lib
cp -rv ${srcdir}/fakeinstall/usr/lib/d3d ${pkgdir}/usr/lib
cp -rv ${srcdir}/fakeinstall/usr/lib/lib{gbm,glapi}.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/libOSMesa.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/libwayland*.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/libxatracker.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/include ${pkgdir}/usr
cp -rv ${srcdir}/fakeinstall/usr/lib/pkgconfig ${pkgdir}/usr/lib/
# remove vulkan headers
rm -rf ${pkgdir}/usr/include/vulkan
install -m755 -d "${pkgdir}/usr/share/licenses/mesa"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa/"
}
package_mesa-libgl() {
pkgdesc="Mesa 3-D graphics library"
depends=('libdrm' 'libxdamage' 'libxshmfence' 'libxxf86vm' 'wayland')
provides=('libgl' 'libegl' 'libgles' 'libglvnd')
conflicts=('libglvnd')
install -m755 -d "${pkgdir}/usr/lib/"
cp -rv ${srcdir}/fakeinstall/usr/lib/libGL.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/libEGL.so* ${pkgdir}/usr/lib/
cp -rv ${srcdir}/fakeinstall/usr/lib/libGLES*.so* ${pkgdir}/usr/lib/
install -m755 -d "${pkgdir}/usr/share/licenses/mesa-libgl"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-libgl/"
}
package_mesa-libcl-icd() {
pkgdesc="Mesa OpenCL ICD Bindings"
depends=('expat' 'gcc-libs' 'libdrm' 'libedit' 'libelf' 'libffi' 'llvm-libs' 'ncurses' 'zlib')
optdepends=('opencl-driver: packaged opencl driver')
provides=('opencl-icd-loader' 'ocl-icd' 'libcl')
conflicts=('ocl-icd' 'libcl')
install -m755 -d ${pkgdir}/usr/lib
cp -rv ${srcdir}/openclinstall/usr/lib/libOpenCL* ${pkgdir}/usr/lib/
install -m755 -d "${pkgdir}/usr/share/licenses/mesa-libcl-icd"
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-libcl-icd/"
}
|
