libre/mate-icon-theme-faenza/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Contributor (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=mate-icon-theme-faenza
pkgver=1.18.0
pkgrel=1.parabola1
pkgdesc="Faenza icon theme for MATE, without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('GPL')
makedepends=('mate-common')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha1sums=('1def73aaa5e5ee3588ae6bb2315c833adddcc322')

prepare() {
    cd ${pkgname}-${pkgver}
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype playonlinux picasa spotify; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd ${pkgname}-${pkgver}
    ./autogen.sh
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd ${pkgname}-${pkgver}
    make DESTDIR="${pkgdir}" install
}