blob: 4538dc21ff42f31d1f9a162eb7116f2c98d806c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 204308 2017-01-02 17:15:04Z arojas $
# Maintainer (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): flixie <69one@gmx.net>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=luxrender
pkgver=1.6
_pkgver=b3f85cf7742f
pkgrel=6.parabola1
pkgdesc="Rendering system for physically correct, unbiased image synthesis, with opencl-mesa recommendation"
arch=('x86_64')
url="http://www.luxrender.net/"
license=('GPL')
depends=('boost-libs' 'embree' 'freeimage' 'openexr' 'openimageio' 'libpng' 'opencl-icd-loader' 'libgl' 'fftw')
optdepends=('blender-addon-luxrender: Blender exporter' 'qt4: Qt GUI' \
'python: pylux Python interface'
'opencl-mesa: OpenCL support for AMD GPUs')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python' 'opencl-headers')
conflicts=("$pkgname-libre" "$pkgname-parabola")
replaces=("$pkgname-libre" "$pkgname-parabola")
source=($pkgname-$pkgver.tar.bz2::https://bitbucket.org/luxrender/lux/get/v${pkgver/./}.tar.bz2 \
force_python3.diff)
md5sums=('e40812e4e5a2bb1a58bcbd2a298ba9ee'
'42692e65eabc5828693e2682e94b7c64')
prepare() {
cd "$srcdir"/luxrender-lux-$_pkgver
patch -Np1 < "$srcdir/force_python3.diff"
}
build() {
cd "$srcdir"/luxrender-lux-$_pkgver
cmake . \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLUXRAYS_DISABLE_OPENCL=OFF \
-DPYTHON_CUSTOM=ON \
-DPYTHON_LIBRARIES=/usr/lib/libpython3.6m.so \
-DPYTHON_INCLUDE_PATH=/usr/include/python3.6m/ \
-DCMAKE_EXE_LINKER_FLAGS=-lpthread
make
}
package() {
cd "$srcdir"/luxrender-lux-$_pkgver
make DESTDIR="$pkgdir" install
# fix library path on x86_64
[ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib
# install pylux
install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.6/pylux.so
}
# vim:set ts=2 sw=2 et:
|
