blob: ff5383197338142c8b55dce64ea4513fc89009f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Based on linux-api-headers package
# toolchain build order: linux-libre-api-headers->glibc->binutils->gcc->binutils->glibc
pkgname=linux-libre-api-headers
_pkgbasever=4.4-gnu
_pkgver=4.4.1-gnu
_srcname=linux-${_pkgbasever%-*}
pkgver=${_pkgver//-/_}
pkgrel=1
pkgdesc="Kernel headers sanitized for use in userspace"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.gnu.org/software/libc"
license=('GPL2')
provides=('linux-api-headers')
conflicts=('linux-api-headers')
replaces=('linux-api-headers')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.xz"
"http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.xz.sign"
"http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.xz"
"http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.xz.sign")
sha256sums=('f53e99866c751f21412737d1f06b0721e207f495c8c64f97dffb681795ee69a0'
'SKIP'
'ed09b329d879bb758374b6a76acb841cdf63a6638720378657fb2b6eeed6b265'
'SKIP')
validpgpkeys=(
'474402C8C582DAFBE389C427BCB7CF877E7D47A7' # Alexandre Oliva
)
prepare() {
cd "${srcdir}/${_srcname}"
# add upstream patch
if [ "${_pkgbasever}" != "${_pkgver}" ]; then
patch -p1 -i "${srcdir}/patch-${_pkgbasever}-${_pkgver}"
fi
}
build() {
cd "${srcdir}/${_srcname}"
make mrproper
make headers_check
}
package() {
cd "${srcdir}/${_srcname}"
make INSTALL_HDR_PATH="${pkgdir}"/usr headers_install
# use headers from libdrm
rm -r "${pkgdir}"/usr/include/drm
# clean-up unnecessary files generated during install
find "${pkgdir}" \( -name .install -o -name ..install.cmd \) -delete
}
|
