blob: d3a684963b1df2fa952683ef594f9863de230e9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgbase=libretools
pkgname=(libretools librelib gitget xbs)
pkgdesc="Programs for Parabola development"
url="https://git.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')
pkgver=20170709.1
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig})
sha256sums=('1d74e007a33e46db11ecb14d7e501eabb3f6f4feb18d223329de9ce68cd70c91'
'SKIP')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker
pkgrel=1
arch=('any')
makedepends=(ruby-ronn)
checkdepends=(sh-roundup git expac tokyocabinet)
build() {
cd "$srcdir/$pkgbase-$pkgver"
make
}
check() {
cd "$srcdir/$pkgbase-$pkgver"
SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}
package_librelib() {
pkgdesc="The shell library portion of libretools"
license=(GPL2)
optdepends=(
'libretools: for libreblacklist/blacklist.sh'
'wget: for libreblacklist/blacklist.sh'
)
cd "$srcdir/$pkgbase-$pkgver"
make install-librelib DESTDIR="$pkgdir"
}
package_gitget() {
pkgdesc="A simple to use downloader for git URLs"
license=(GPL2)
depends=("librelib=$pkgver" git)
provides=("libregit=$pkgver")
conflicts=("libregit")
replaces=("libregit")
cd "$srcdir/$pkgbase-$pkgver"
make install-gitget DESTDIR="$pkgdir"
}
package_xbs() {
pkgdesc='A tool for working with arbitrary ABS-like build systems'
backup=(etc/xbs/xbs.conf
etc/xbs/xbs-abs.conf)
license=(GPL2)
depends=(
"gitget=$pkgver" # `helper-abslibre`
"librelib=$pkgver"
subversion # `helper-abs`
)
cd "$srcdir/$pkgbase-$pkgver"
make install-xbs DESTDIR="$pkgdir"
}
package_libretools() {
backup=(etc/libretools.conf
etc/libretools.d/chroot.conf
etc/libretools.d/libredbdiff.conf
etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools libretools-mips64el)
replaces=(libretools-mips64el)
depends=(
"librelib=$pkgver"
"xbs=$pkgver" # `createworkdir`, `librestage`
'pacman>=5.0.1-2.parabola4' 'pacman<5.1'
arch-install-scripts # `mkarchroot` uses `pacstrap`
expac # `libredbdiff`
make # `librefetch`
openssh # `librerelease`
rsync # `librerelease` and `makechrootpkg.sh`
systemd # systemd-nspawn
tokyocabinet # `toru`
#namcap # Namcap is currently dissabled in libremakepkg :-(
#subversion # `diff-unfree` # ignore because of xbs
wget # `aur`, optdepend for librelib:`blacklist`
)
optdepends=(
'binfmt-qemu-static: To build ARM packages from x86'
)
cd "$srcdir/$pkgbase-$pkgver"
make install-libretools DESTDIR="$pkgdir"
}
|
