blob: 2312689302e559acb233302fe2522ace6f27555e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@lavabit.com>
pkgbase=libretools
pkgname=(libretools libretools-mips64el librelib)
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/packages/libretools.git/"
license=('GPL3' 'GPL2')
pkgver=20130714
_libretools_commit=bb42528084058af8dc42c315d5f013af05741bb1
_devtools_commit=bf8513ae631484a0c292ad085ea7ede9859f8e0f
_packages_url=https://projects.parabolagnulinux.org/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)
pkgrel=1
arch=('any')
makedepends=(emacs) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup)
build() {
cd "$srcdir"
ln -sf devtools-par-$_devtools_commit devtools-par
cd "$srcdir/$pkgbase-$_libretools_commit"
make build-libretools build-libretools-mips64el build-librelib build-doc
}
check() {
cd "$srcdir/$pkgbase-$_libretools_commit"
make check TESTENVFLAGS='--no-network --no-sudo'
}
package_librelib() {
pkgdesc="Shell library portion of libretools"
depends=(
wget # `aur` and `lib/blacklist.sh`
)
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-librelib DESTDIR="$pkgdir"
}
package_libretools() {
backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
install=libretools.install
replaces=(chroottools)
conflicts=(devtools)
depends=(
"librelib=$pkgver"
arch-install-scripts # `archroot` uses `pacstrap`
git # `createworkdir` and `libregit` (also mips-add in -mips64el)
openssh # `librerelease`
rsync # `librerelease` and `makechrootpkg.sh`
subversion # `diff-unfree`
tokyocabinet # `treepkg`
)
optdepends=('namcap: to check package files')
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-libretools install-doc DESTDIR="$pkgdir"
}
package_libretools-mips64el() {
pkgdesc="Scripts for Parabola development (for mips64el architecture)"
depends=("$pkgbase=$pkgver")
cd "$srcdir/$pkgbase-$_libretools_commit"
make install-libretools-mips64el DESTDIR="$pkgdir"
}
md5sums=('a8c4c3552bde5185dec637471b890256'
'b28b1492fda205be7c577fc03cbc3399')
|
