blob: 4bc79001f8743d75d8168ce3f9a264817543fc48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 161946 2016-02-17 08:20:04Z arojas $
# Maintainer (Arch): Federico Cinelli <cinelli@aur.archlinux.org>
# Maintainer (Arch): Mateusz Herych <heniekk@gmail.com>
# Contributor: Jorge Lopez <jorginho@lavabit.com>
pkgname=libquicktime
pkgver=1.2.4
pkgrel=15.parabola1
pkgdesc="A library for reading and writing quicktime files, without nonfree faac support"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
url="http://libquicktime.sourceforge.net/"
depends=('alsa-lib' 'faad2' 'gtk2' 'lame' 'libjpeg-turbo' 'libxaw'
'libxv' 'schroedinger'
'libavcodec.so' 'libswscale.so' 'libvorbisenc.so' 'libvorbisfile.so'
'libvorbis.so' 'libx264.so')
makedepends=('mesa-libgl')
source=("http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz"
ffmpeg2.0.patch libquicktime-ffmpeg3.patch)
sha256sums=('1c53359c33b31347b4d7b00d3611463fe5e942cae3ec0fefe0d2fd413fd47368'
'a1c8415e8e7bc04c81b946b9e3746f7d5ef24819135962280c3a7ddb3f2baa2b'
'5513f628866de253031de2761d27c2be3965e90b70d10a494446a96d851c0729')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
prepare() {
cd $pkgname-$pkgver
patch -Np1 -i ../ffmpeg2.0.patch
# Fix build with ffmpeg 3.0 (Gentoo)
patch -p1 -i ../libquicktime-ffmpeg3.patch
}
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--enable-gpl \
--with-ffmpeg \
--with-x264 \
--without-doxygen \
--without-faac
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
