blob: 6c08f8b06dc6b1798b990bd805a869a254a4e8c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 161946 2016-02-17 08:20:04Z arojas $
# Maintainer (Arch): Federico Cinelli <cinelli@aur.archlinux.org>
# Maintainer (Arch): Mateusz Herych <heniekk@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Jorge Lopez <jorginho@lavabit.com>
pkgname=libquicktime
pkgver=1.2.4
pkgrel=19.parabola1
pkgdesc="A library for reading and writing quicktime files, without nonfree faac support"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
url="http://libquicktime.sourceforge.net/"
depends=('alsa-lib' 'faad2' 'gtk2' 'lame' 'libjpeg-turbo' 'libxaw'
'libxv' 'schroedinger'
'libavcodec.so' 'libswscale.so' 'libvorbisenc.so' 'libvorbisfile.so'
'libvorbis.so' 'libx264.so')
makedepends=('mesa-libgl')
source=("http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz"
CVE-2016-2399.patch
libquicktime-1.2.4-ffmpeg2.patch
libquicktime-1.2.4-ffmpeg29.patch
libquicktime-1.2.4-ffmpeg4.patch)
sha256sums=('1c53359c33b31347b4d7b00d3611463fe5e942cae3ec0fefe0d2fd413fd47368'
'006c6be761075ca25217fe510e1ec7cfbb6262c3d758c1bd629719072ddb0935'
'2c7bb532ea8ac3b0e7a9a76ca6ad41127810529e7f7c2faac6f1e2f7c5c4bb93'
'c3a8dfb6bfb69c2b54aeafe3306a8af1fff5a3a06fd05b28725d3ea7688ce2cd'
'd4582dc2ed389acd01080690a95643277e43955adcb4058132506c5b437d044f')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
prepare() {
cd $pkgname-$pkgver
# apply patches from gentoo https://gitweb.gentoo.org/repo/gentoo.git/tree/media-libs/libquicktime/files
patch -p1 -i "$srcdir/CVE-2016-2399.patch"
patch -p1 -i "$srcdir/libquicktime-1.2.4-ffmpeg2.patch"
patch -p1 -i "$srcdir/libquicktime-1.2.4-ffmpeg29.patch"
patch -p1 -i "$srcdir/libquicktime-1.2.4-ffmpeg4.patch"
for FILE in lqt_ffmpeg.c video.c audio.c ; do
sed -i -e "s:CODEC_ID_:AV_&:g" "plugins/ffmpeg/${FILE}"
done
}
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--enable-gpl \
--with-ffmpeg \
--with-x264 \
--without-doxygen \
--without-faac
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
