blob: 6c319e676cada1a76967951486b08d386073755a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgbasename=sdl-libre
pkgname=lib32-$_pkgbasename
pkgver=1.2.15
pkgrel=3
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (32-bit)"
arch=('x86_64')
url="http://www.libsdl.org"
license=('LGPL')
provides=("lib32-sdl=${pkgver}")
conflicts=('lib32-sdl')
replaces=('lib32-sdl')
depends=('lib32-libxext' 'lib32-libxrender' 'lib32-libx11' $_pkgbasename)
makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' gcc-multilib)
optdepends=('lib32-alsa-lib: ALSA audio driver'
'lib32-libpulse: PulseAudio audio driver')
options=('!libtool')
source=(http://www.libsdl.org/release/SDL-${pkgver}.tar.gz
sdl-1.2.14-fix-mouse-clicking.patch
sdl-1.2.14-disable-mmx.patch
fix_joystick_misc_axes.diff
libsdl-1.2.15-resizing.patch
libre.patch)
md5sums=('9d96df8417572a2afb781a7c4c811a85'
'04d8c179f125e04bcd4c9d60e013c2d7'
'e5c16b7611f62c7cb25f0534eff68852'
'687586a108b597a2a6b73070c1d37e51'
'3dd50347d8856160a9cbd7f80383a1f8'
'5c665f72b8a2adc97a91f6db6f2da79a')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd SDL-$pkgver
patch -Np1 -i ../sdl-1.2.14-fix-mouse-clicking.patch
patch -Np1 -i ../sdl-1.2.14-disable-mmx.patch
patch -Np1 -i ../fix_joystick_misc_axes.diff
patch -Np1 -i ../libsdl-1.2.15-resizing.patch
patch -Np0 -i ../libre.patch
./configure --prefix=/usr --disable-nasm --enable-alsa \
--with-x --disable-rpath --disable-static --libdir=/usr/lib32
make
}
package() {
cd SDL-$pkgver
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir"/usr/{include,share}
cd "$pkgdir/usr/bin"
mv sdl-config sdl-config-32
}
|
