blob: a02382eddb677dc70205e68ce28737ccc5ca0701 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
pkgname=kopete
pkgver=19.12.3
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Instant Messenger'
pkgdesc+=', without nonfree Skype support'
url='https://kde.org/applications/internet/kopete/'
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL LGPL FDL)
groups=(kde-applications kdenetwork)
depends=(knotifyconfig kcmutils ktexteditor kcontacts kidentitymanagement libkleo qca kdelibs4support khtml
libidn libotr)
makedepends=(extra-cmake-modules mediastreamer libgadu jsoncpp kdoctools kdesignerplugin kdnssd libkleo ktexteditor kinit)
optdepends=('mediastreamer: jingle support' 'libgadu: Gadu-Gadu protocol' 'kdnssd: bonjour protocol')
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
kopete-mediastreamer2.14.patch kopete-srtp2.patch kopete-openssl-1.1.patch kopete-mediastreamer-4.3.patch)
sha256sums=('8d58fb0c9dd8b651bfc996e6928f7ccdad8e21cba39ffd0e54d46f7145fa7b27'
'SKIP'
'8b8e7a5d9f17fafdddb402fab22b0b8d9963039ea8ea9fa749cad67aeeb879ac'
'ceed663f7007654d186d918cf7a0742972ed5bd319879021e9ba80e395177700'
'a12ea422e5162ef11274a98fd53658d6e780cafbe2e0fac70c8bc7d3291fef8b'
'7ff38588f25bc05eae8ba20d9624536b33addf26b74e8c64ac036291f98f2bc2')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd $pkgname-$pkgver
# based on https://devel.trisquel.info/trisquel/package-helpers/blob/belenos/helpers/make-kopete
sed -i 's/Skype protocol" ON/Skype protocol" OFF/g' protocols/CMakeLists.txt
rm -rf protocols/skype
sed 's/, Skype//' -i ./doc/index.docbook
# fix build with mediastreamer 2.14 https://phabricator.kde.org/D15956
patch -p1 -i ../kopete-mediastreamer2.14.patch
# Detect mediastreamer 4.3
patch -p1 -i ../kopete-mediastreamer-4.3.patch
# fix build with OpenSSL 1.1 (Fedora patch)
patch -p1 -i ../kopete-openssl-1.1.patch
# support SRTP2
patch -p1 -i ../kopete-srtp2.patch
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DBUILD_TESTING=OFF \
-DWITH_skype=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
