1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# $Id: PKGBUILD 290650 2017-03-12 00:23:05Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
pkgname=kio
pkgver=5.37.0
pkgrel=3.parabola1
pkgdesc='Resource and network access abstraction, without non-privacy search engines'
arch=('i686' 'x86_64' 'armv7h')
url='https://community.kde.org/Frameworks'
license=('LGPL')
depends=('solid' 'kjobwidgets' 'kbookmarks' 'libxslt' 'kwallet' 'desktop-file-utils' 'opengl-driver')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'doxygen' 'qt5-tools')
optdepends=('kio-extras: extra protocols support (sftp, fish and more)'
'kdoctools: for the help kioslave'
'knetattach: to add new kio-remote entries')
groups=('kf5')
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig}
kio-no-kinit-dependency.patch::"https://cgit.kde.org/kio.git/patch/?id=c85a8e03"
kio-no-kinit-dependency2.patch::"https://cgit.kde.org/kio.git/patch/?id=e72b70a0"
'duckduckgo_html.desktop'
'duckduckgo_lite.desktop')
sha256sums=('49448ebcfe182805f8f9cd40c1e2c8e686578cc2e7fa3688204d5ca4e182ac5b'
'SKIP'
'c4bfae6a1fb228bf009d7b7a0e3cb34ed0be3bfce4293f543084e4e450577c4a'
'6a08f516224e4031529b8266e2c2cfb85522bc62d50eadd4d2e625373790460b'
'31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
'40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d')
validpgpkeys=('53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB') # David Faure <faure@kde.org>
prepare() {
mkdir -p build
cd ${pkgname}-${pkgver}
# prevent circular dependency kio <-> kinit
patch -p1 -i ../kio-no-kinit-dependency.patch
patch -p1 -i ../kio-no-kinit-dependency2.patch
# Removing non-privacy search providers
rm -v src/urifilters/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop
# Adding DuckDuckGo HTML
cp -v "${srcdir}"/duckduckgo_html.desktop src/urifilters/ikws/searchproviders
# Adding DuckDuckGo Lite
cp -v "${srcdir}"/duckduckgo_lite.desktop src/urifilters/ikws/searchproviders
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DKDE_INSTALL_LIBEXECDIR=lib \
-DBUILD_TESTING=OFF \
-DBUILD_QCH=ON
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|
