blob: 9918f25974b96aa3411ab2464cbc03d4c79904aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: grizzlyuser <grizzlyuser@protonmail.com>
# rational for inclusion in libre:
# - removed support for not freedom-respecting search engines
pkgname=kio
pkgver=5.73.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Resource and network access abstraction'
pkgdesc+=', only with search engines that claim to respect user privacy and do not serve nonfree JavaScript'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(solid kjobwidgets kbookmarks libxslt kwallet ktextwidgets kded)
makedepends=(extra-cmake-modules kdoctools doxygen qt5-tools qt5-doc)
optdepends=('kio-extras: extra protocols support (sftp, fish and more)' 'kdoctools: for the help kioslave'
'knetattach: to add new kio-remote entries' 'kio-fuse: to mount remote filesystems via FUSE')
groups=(kf5)
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
source+=(duckduckgo_{html,lite}.desktop)
sha256sums=('05da159e6cf5ef9aa4dd7ede86ce28a5581624a1b3f0b4718c5b7e30c4aa2a66'
'SKIP')
sha256sums+=('31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
'40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>
prepare() {
cd $pkgname-$pkgver
# Removing search providers
rm -v src/urifilters/ikws/searchproviders/*.desktop
# Adding DuckDuckGo HTML and DuckDuckGo Lite
# Contributions of other search engines that satisfy pkgdesc are welcome!
cp -v "$srcdir"/duckduckgo_{html,lite}.desktop src/urifilters/ikws/searchproviders
}
build() {
cmake -B build -S $pkgname-$pkgver \
-DCMAKE_INSTALL_LIBEXECDIR=lib \
-DBUILD_TESTING=OFF \
-DBUILD_QCH=ON
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|
