blob: 96bcbfd4ceecc9c9beb7b301dbe4c1531e8ef647 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 291158 2017-03-21 20:15:40Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Antonio Rojas
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
pkgname=kinfocenter
pkgver=5.10.5
pkgrel=1.parabola1
pkgdesc='A utility that provides information about a computer system (Parabola rebranded)'
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/applications/system/kinfocenter/'
license=('LGPL')
depends=('kcmutils' 'pciutils' 'glu' 'libraw1394' 'kwayland')
makedepends=('extra-cmake-modules' 'python' 'plasma-framework' 'kdoctools')
conflicts=('kdebase-workspace')
groups=('plasma')
source=("https://download.kde.org/stable/plasma/${pkgver}/$pkgname-$pkgver.tar.xz"{,.sig}
'parabola-logo.svg::https://wiki.parabola.nu/images/a/af/Parabolagnu%2Blinuxlibre-dark-scalable.svg'
'kcm-about-distrorc')
sha512sums=('556bb7e369f28ce1203129f02009bc01d3c018e6e0cc7c3c18382fdc7bb6fa54e9056deb5ffbfcb429853b5f0076e537ce01be721cf698d493a531777ef1225f'
'SKIP'
'af9f9a8074cb84e3a2ab35200189627d8fb529741aa9c2a316c6c6f049ffd88b6b16d98f1fcdef731a9f75a03883b6806fb48c87c533b94ab3e719bdc02f7b9f'
'2a184861ce8aae52c98a143d3c905f74c03ccf10294234293f7eb647b663e9b0f95f2a45c3681e7948ddbdae082d51f9cd830e355302fdcd876a6d5be4ce557b')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E' # Jonathan Riddell
'348C8651206633FD983A8FC4DEACEA00075E1D76' # KDE Neon
'D07BD8662C56CB291B316EB2F5675605C74E02CF') # David Edmundson
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
# Install Parabola logo
install -Dm644 "$srcdir"/parabola-logo.svg "$pkgdir"/usr/share/about-distro/parabola-logo.svg
install -Dm644 "$srcdir"/kcm-about-distrorc "$pkgdir"/etc/xdg/kcm-about-distrorc
}
|
