blob: f7393f7f589b5612b4c69b43af204e3247dec289 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 288944 2017-02-14 17:56:57Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Antonio Rojas
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=khotkeys
pkgver=5.9.2
pkgrel=1.parabola1
pkgdesc='KHotKeys, with DuckDuckGo HTML support'
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/workspaces/plasmadesktop/'
license=('LGPL')
depends=('plasma-workspace')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'kdesignerplugin')
conflicts=('kdebase-workspace')
groups=(plasma)
source=("http://download.kde.org/stable/plasma/${pkgver}/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('88d1633e7271e8d90814501d10d2e393f3d43428ad0240e8f03bb9fa7c348e26'
'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E' # Jonathan Riddell
'348C8651206633FD983A8FC4DEACEA00075E1D76' # KDE Neon
'D07BD8662C56CB291B316EB2F5675605C74E02CF') # David Edmundson
prepare() {
mkdir -p build
cd ${pkgname}-${pkgver}
sed -i 's|google[.]com|duckduckgo.com/html|' data/defaults.khotkeys
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|
