blob: e1c1127d4b022c7fe8f7c31d091f966bb7411e98 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 217366 2014-07-18 11:50:35Z svenstaro $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
_pkgname=kdeutils-ark
pkgname=kdeutils-ark-libre
pkgver=4.13.3
pkgrel=1
pkgdesc='Archiving Tool, with unar support'
url='http://kde.org/applications/utilities/ark/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdeutils')
provides=("kdeutils-ark=$pkgver")
replaces=('kdeutils-ark')
conflicts=('kdeutils-ark')
depends=('kdebase-runtime' 'kdebase-lib' 'libarchive' 'qjson')
makedepends=('cmake' 'automoc4')
optdepends=('p7zip' 'zip' 'unzip' 'unar')
install=${_pkgname}.install
source=("http://download.kde.org/stable/${pkgver}/src/ark-${pkgver}.tar.xz"
'ark-unar-06.patch')
sha1sums=('432afb91b79e95b10a0d15ed13697e8c4ecf99d3'
'a0a836950f185d9b2245204579f969203036fdec')
prepare() {
cd "${srcdir}/ark-${pkgver}"
# This patch will allow Ark to use The Unarchiver command line utilities (unar/lsar) to operate on RAR files, particularly RARv3.
patch -Np1 -i "${srcdir}/ark-unar-06.patch"
}
build() {
cd "${srcdir}"
mkdir build
cd build
cmake ../ark-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd $srcdir/build
make DESTDIR=$pkgdir install
}
|
