blob: c80c13b49b2f16b4a50e88f71da8da21d4018315 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Zuf <kontakt.zuf@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
# parabola changes and rationale:
# - arch package links to qt5-webengine
# - no changes necessary - simply rebuild without qt5-webengine in the environment
pkgname=kdenlive
pkgver=21.04.1
pkgrel=1
pkgrel+=.parabola1
pkgdesc='A non-linear video editor for Linux using the MLT video framework'
arch=(x86_64)
arch+=(armv7h i686)
url='https://apps.kde.org/kdenlive/'
license=(GPL)
groups=(kde-applications kde-multimedia)
depends=(qt5-networkauth knewstuff knotifyconfig kfilemetadata purpose mlt6 rttr breeze-icons frei0r-plugins)
makedepends=(extra-cmake-modules kdoctools v4l-utils)
# makedepends_i686=('kcodecs>=5.79.0' 'kconfig>=5.79.0') # in [testing]
optdepends=('ffmpeg: for FFmpeg plugin'
'cdrtools: for creation of DVD ISO images'
'dvdauthor: for creation of DVD'
'dvgrab: for firewire capture'
'recordmydesktop: for screen capture'
'xine-ui: for DVD preview'
'vlc: for DVD preview'
'opencv: for motion tracking'
'plasma-desktop: theme configuration'
'opentimelineio: timeline export/import')
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig}
kdenlive-mlt6.patch)
sha256sums=('9c2d0bc76b86fdf83cae1ac8c40b7630afbce4b92f9fd095bcfba1186851ef41'
'SKIP'
'db0819cea73fc7c2926c39a3de66fba86e94a6ca2e1f97e7bad1166ac6aec5bb')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87 # Christoph Feck <cfeck@kde.org>
D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
prepare() {
patch -d $pkgname-$pkgver -p1 < kdenlive-mlt6.patch # Use melt6 executable name
}
build() {
cmake -B build -S $pkgname-$pkgver \
-DBUILD_TESTING=OFF \
-DCRASH_AUTO_TEST=ON
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|
