blob: ee59492ad73dbe9c6e1aff0b560ae5d6c57cdd39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 243760 2015-08-15 17:04:46Z arojas $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=kdenetwork-kopete
pkgver=15.08.0
pkgrel=1.parabola1
pkgdesc='Instant Messenger, without nonfree Skype support'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdenetwork')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=('kdebase-runtime' 'kdepimlibs4' 'qca-ossl' 'libotr' 'qimageblitz' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost' 'mediastreamer' 'libgadu')
optdepends=('mediastreamer: jingle support' 'libgadu: Gadu-Gadu protocol')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz")
sha1sums=('b7ee954b96d10be94fa59b99ecdf302ba73c88f8')
prepare() {
cd kopete-${pkgver}
# Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
rm -rv protocols/skype
sed 's/, Skype//' -i doc/index.docbook
cd ..
mkdir -p build
}
build() {
cd build
cmake ../kopete-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_SKIP_RPATH=ON \
-DWITH_Libmsn=OFF \
-DWITH_skype=OFF
make
}
package() {
cd build
make DESTDIR=$pkgdir install
}
|
