blob: 0c539fd773280b87221f9c71aae53140d498e1f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
pkgname=kdenetwork-kopete
pkgver=17.08.3
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)
pkgdesc="Instant Messenger, without nonfree Skype support"
url="https://kde.org/applications/internet/kopete/"
license=(GPL LGPL FDL)
makedepends=(cmake automoc4 boost mediastreamer libgadu jsoncpp openssl-1.0)
depends=(kdebase-runtime libotr qimageblitz kdepimlibs4 qca-qt4)
optdepends=('mediastreamer: jingle support'
'libgadu: Gadu-Gadu protocol'
'openssl-1.0: jingle support')
groups=(kde-applications kdenetwork)
source=("https://download.kde.org/stable/applications/$pkgver/src/kopete-$pkgver.tar.xz"{,.sig}
'kopete-mediastreamer2.14.patch'
'kopete-pthread-link.patch')
sha256sums=('f86ccc1ca809c723d1baf2eed745f158337059263555f6fafa23ea200aacafec'
'SKIP'
'c34a268aaa058e563174581dbe37c15fed91e82326ec704d2a872463139865e0'
'a7ebdd8dd4336b7ec085ef254bf18040f473b73379a8cd84569b28441a6c71df')
validpgpkeys=('CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7' # Albert Astals Cid <aacid@kde.org>
'F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87') # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd kopete-$pkgver
# Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
rm -rv protocols/skype
sed 's/, Skype//' -i doc/index.docbook
# Fix build with mediastreamer 2.14
patch -p1 -i $srcdir/kopete-mediastreamer2.14.patch
# Fix linking to pthread in libjingle-call
patch -p1 -i $srcdir/kopete-pthread-link.patch
# Fix build with OpenSSL 1.1 (based on Fedora patch for libjingle)
# cd protocols/jabber/libjingle
# patch -p1 -i $srcdir/kopete-openssl-1.1.patch
}
build() {
cd build
cmake ../kopete-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_SKIP_RPATH=ON \
-DWITH_Libmsn=OFF \
-DOPENSSL_INCLUDE_DIR=/usr/include/openssl-1.0 \
-DOPENSSL_SSL_LIBRARY=/usr/lib/openssl-1.0/libssl.so \
-DOPENSSL_CRYPTO_LIBRARY=/usr/lib/openssl-1.0/libcrypto.so \
-DWITH_skype=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
