1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net
pkgname=kdebase-runtime
pkgver=17.04.2
pkgrel=1.parabola1
pkgdesc="Plugins and applications necessary for the running of KDE applications, without non-privacy search engines"
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/'
license=('GPL' 'LGPL')
makedepends=('pkg-config' 'cmake' 'automoc4' 'openslp' 'doxygen' 'networkmanager' 'boost')
depends=('kdelibs' 'smbclient' 'libssh' 'libcanberra' 'oxygen-icons' 'xorg-xauth' 'libwebp' 'exiv2' 'gpgme')
optdepends=('drkonqi: crash report tool' 'khelpcenter: to display applications documentation')
provides=(notification-daemon)
conflicts=(kdesu4)
replaces=(kdesu4)
source=("https://download.kde.org/stable/applications/${pkgver}/src/kde-runtime-${pkgver}.tar.xz"{,.sig}
'duckduckgo_html.desktop'
'duckduckgo_lite.desktop'
kdebase-runtime-no-html-thumbnails.patch
kdebase-runtime-no-kdewebkit.patch)
sha512sums=('cd786a40ef5c526721f66eeeaf47b0919cb651f1c67bd82b705d493d4ba45901d208ca0f594cf5b73da73c05354dc5eb4a3a00247667aa59373bd032fc8421fa'
'SKIP'
'7591af1c513b7dfb1c875ea05883d81814878972b859d2bbefb31a2d015781b0f7aa62b4e1773575e35808c85911ed4ca7700761e4370452b48f4d823883e370'
'b138fab47b9648cfe73ea42433df13e19da419b7cdfa8d7ef2e8e9e912e399da376e763c1e950a9ab89ab8bb79bb8bab344663e1dd73bfbe2d87325ae0de1847'
'97f566da7b8887de70d5ff57d2d6c79152702793ce0f5ae55942cc1da0c79a12ade217f106ec29f51773722317f9230da59988813e1434712b703030ea1e35d3'
'dd7eba49ae653b7a3b517fc48bbc289a2f1d258348af1b5bb7b00f2954bf55a9317b7c002a1b796f48046e4d8bb6aac74a69e3c8fa908249841592c246cf28b0')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>
prepare() {
mkdir -p build
cd kde-runtime-${pkgver}
# Don't link to kactivities
sed -e '/plasmaextracomponents/d' -i plasma/declarativeimports/CMakeLists.txt
# Drop HTML thumbnailer, uses insecure QtWebKit
patch -p1 -i ../kdebase-runtime-no-html-thumbnails.patch
patch -p1 -i ../kdebase-runtime-no-kdewebkit.patch
# Removing non-privacy search providers
rm -v kurifilter-plugins/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop
# Adding DuckDuckGo HTML
cp -v "${srcdir}"/duckduckgo_html.desktop kurifilter-plugins/ikws/searchproviders
# Adding DuckDuckGo Lite
cp -v "${srcdir}"/duckduckgo_lite.desktop kurifilter-plugins/ikws/searchproviders
}
build() {
cd build
cmake ../kde-runtime-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_SKIP_RPATH=ON \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWITH_QNtrack=OFF \
-DSAMBA_INCLUDE_DIR=/usr/include/samba-4.0 \
-DWITH_NepomukCore=OFF \
-DBUILD_khelpcenter=OFF \
-DBUILD_kglobalaccel=OFF \
-DBUILD_kuiserver=OFF \
-DBUILD_drkonqi=OFF \
-DBUILD_doc=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
rm "$pkgdir"/usr/share/icons/hicolor/index.theme
ln -s /usr/lib/kde4/libexec/kdesu "$pkgdir"/usr/bin/kdesu4
# Use KF5 drkonqi
ln -s /usr/lib/drkonqi "$pkgdir"/usr/lib/kde4/libexec/
# FS#36668
chown :nobody "$pkgdir"/usr/lib/kde4/libexec/kdesud
chmod g+s "$pkgdir"/usr/lib/kde4/libexec/kdesud
}
|
