blob: e563d133ca27881f3c68c0978c0cbdfed3ee17de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor (ConnochaetOS): Henry Jensen <hjensen@connochaetos.org>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: vando <facundo@esdebian.org>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Contributor: Figue <ffigue at gmail>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com>
_pgo=true
pkgname=icecat
_pkgver=38.6.0-gnu1
pkgver=${_pkgver//-/_}
pkgrel=2
pkgdesc="GNU IceCat, the standalone web browser based on Mozilla Firefox."
arch=(i686 x86_64)
license=(MPL GPL LGPL)
depends=(alsa-lib dbus-glib desktop-file-utils gtk2 hicolor-icon-theme hunspell icu=56.1 libevent libvpx=1.5.0 libxt mime-types mozilla-common mozilla-searchplugins nss sqlite startup-notification ttf-font)
makedepends=(diffutils gst-plugins-base-libs imake inetutils libpulse mesa python2 unzip yasm zip)
options=(!emptydirs !makeflags debug)
if $_pgo; then
makedepends+=(xorg-server-xvfb)
options+=(!ccache)
fi
optdepends=('networkmanager: Location detection via available WiFi networks'
'gst-plugins-good: h.264 video'
'gst-libav: h.264 video')
url="http://www.gnu.org/software/gnuzilla/"
install=$pkgname.install
source=(http://ftp.gnu.org/gnu/gnuzilla/${_pkgver%-*}/$pkgname-$_pkgver.tar.bz2{,.sig}
#mksource=(http://jenkins.trisquel.info/$pkgname/$pkgname-$_pkgver.tar.bz2)
#source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$_pkgver.tar.bz2{,.sig}
mozconfig
libre.patch
gnu_headshadow.png
$pkgname.desktop
$pkgname-install-dir.patch
vendor.js
$pkgname-fixed-loading-icon.png
remove-google-play-services-support.patch
disable-crypto-hardening-settings.patch)
mksha256sums=('1f58676fc0bdf60dc37145b8c97f507f0acec9bc84582aeef703cf0ed9744ed3')
sha256sums=('9d0e10005c28d130d262176280656dc3cf374717723bd715d3d6a3cc5999a42d'
'SKIP'
'33a8cf07373c63a0bea70ec2c3983d2cca990752c0f946cb5dbd91f1e2b6410f'
'dd173c9283babb8a04bf55274de05e823161f7d13adb8c5e21dd5a9c0dc549a2'
'93e3001ce152e1d142619e215a9ef07dd429943b99d21726c25da9ceb31e31cd'
'52df9ffeb52166ed4abd9a132ee4a9017b9c4980f0725ba383610ccfb06d4745'
'5bdab2de5520fb4d3dbc453d9f73d20e0e077bf652bc780fc17184ba6c718a47'
'977aa49b940f1da049cefa2878a63ac6669a78e63e9d55bb11db7b8f8fb64c33'
'68e3a5b47c6d175cc95b98b069a15205f027cab83af9e075818d38610feb6213'
'9e651b0f7e7d9d663e8b24077d52bad15f011871747743aff60d6e2d7a45ae5b'
'bcd351d97e99f9a71ff5f44e29037f5451617378527801e32de514ff30583476')
validpgpkeys=(
'A57369A8BABC2542B5A0368C3C76EED7D7E04784' # Ruben Rodriguez
'C92BAA713B8D53D3CAE63FC9E6974752F9704456' # André Silva
)
prepare() {
export GNU_BUILD="gnuzilla-release"
mv $pkgname-${pkgver%_*} "$srcdir/$GNU_BUILD"
cd "$srcdir/$GNU_BUILD"
# Put gnu_headshadow.png on the source code
install -m644 "$srcdir/gnu_headshadow.png" \
browser/base/content/abouthome
# Install to /usr/lib/$pkgname
patch -Np1 -i "$srcdir/$pkgname-install-dir.patch"
# Patch and remove anything that's left
patch -Np1 -i "$srcdir/libre.patch"
patch -Np1 -i "$srcdir/remove-google-play-services-support.patch"
rm -v browser/base/content/abouthome/snippet*.png || true
sed -i '\|abouthome/snippet|d
' browser/base/jar.mn
# Load our build config, disable SafeSearch
cp "$srcdir/mozconfig" .mozconfig
mkdir "$srcdir/path"
# WebRTC build tries to execute "python" and expects Python 2
ln -s /usr/bin/python2 "$srcdir/path/python"
# Configure script misdetects the preprocessor without an optimization level
# https://bugs.archlinux.org/task/34644
sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' configure
# Fix tab loading icon (doesn't work with libpng 1.6)
# https://bugzilla.mozilla.org/show_bug.cgi?id=841734
cp "$srcdir/$pkgname-fixed-loading-icon.png" \
browser/themes/linux/tabbrowser/loading.png
# Disable crypto hardening settings for now
# https://lists.parabola.nu/pipermail/assist/2015-October/000534.html
# https://labs.parabola.nu/issues/842
patch -Np1 -i "$srcdir/disable-crypto-hardening-settings.patch"
}
build() {
export GNU_BUILD="gnuzilla-release"
cd "$srcdir/$GNU_BUILD"
export PATH="$srcdir/path:$PATH"
export PYTHON="/usr/bin/python2"
if $_pgo; then
# Do PGO
xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" \
make -f client.mk build MOZ_PGO=1
else
make -f client.mk build
fi
}
package() {
export GNU_BUILD="gnuzilla-release"
cd "$srcdir/$GNU_BUILD"
make -f client.mk DESTDIR="$pkgdir" INSTALL_SDK= install
install -Dm644 ../vendor.js "$pkgdir/usr/lib/$pkgname/browser/defaults/preferences/vendor.js"
brandingdir=browser/branding/official
icondir="$pkgdir/usr/share/icons/hicolor"
for i in 16 22 24 32 48 256; do
install -Dm644 "$brandingdir/default$i.png" \
"$icondir/${i}x${i}/apps/$pkgname.png"
done
install -Dm644 "$brandingdir/content/icon64.png" \
"$icondir/64x64/apps/$pkgname.png"
install -Dm644 "$brandingdir/mozicon128.png" \
"$icondir/128x128/apps/$pkgname.png"
install -Dm644 "$brandingdir/content/about-logo.png" \
"$icondir/192x192/apps/$pkgname.png"
install -Dm644 "$brandingdir/content/about-logo@2x.png" \
"$icondir/384x384/apps/$pkgname.png"
install -d "$pkgdir/usr/share/applications"
install -m644 "$srcdir/$pkgname.desktop" \
"$pkgdir/usr/share/applications"
# Use system-provided dictionaries
rm -rf "$pkgdir/usr/lib/$pkgname/"{dictionaries,hyphenation}
ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname/dictionaries"
ln -s /usr/share/hyphen "$pkgdir/usr/lib/$pkgname/hyphenation"
rm -rf "$pkgdir/usr/lib/$pkgname/browser/"{searchplugins,plugins}
ln -sf /usr/lib/mozilla/plugins "$pkgdir/usr/lib/$pkgname/browser/plugins"
ln -sf /usr/lib/mozilla/searchplugins "$pkgdir/usr/lib/$pkgname/browser/searchplugins"
# Workaround for now:
# https://bugzilla.mozilla.org/show_bug.cgi?id=658850
ln -sf $pkgname "$pkgdir/usr/lib/$pkgname/$pkgname-bin"
}
|
