blob: 065d8cf74fe7d21bb8bbd5d46b569e48636942fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Eschwartz <eschwartz93@gmail.com>
pkgname=icecat-noscript
pkgver=5.1.7
pkgrel=1
arch=(any)
pkgdesc="Extension for icecat which disables script"
url="https://noscript.net/"
license=(GPL2)
depends=(icecat)
makedepends=(unzip)
groups=(icecat-addons)
source=(https://secure.informaction.com/download/releases/noscript-$pkgver.xpi)
noextract=("noscript-$pkgver.xpi")
sha256sums=('617f73683acdca7df2a7d08843443d38929afbf40075e113ab3ccab0eef7cd6b')
prepare() {
unzip -qqo "noscript-$pkgver.xpi" -d "noscript-$pkgver"
}
package() {
_extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' noscript-$pkgver/install.rdf)"
_extension_dest="$pkgdir/usr/lib/icecat/browser/extensions/$_extension_id"
if grep '<em:unpack>true</em:unpack>' noscript-$pkgver/install.rdf > /dev/null; then
install -dm755 "$_extension_dest"
cp -R noscript-$pkgver/* "$_extension_dest"
chmod -R ugo+rX "$_extension_dest"
else
install -Dm644 noscript-$pkgver.xpi "$_extension_dest.xpi"
fi
}
|
