blob: 39b552378f05d3d20b1051d6ef0677d5d0d7a2f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id$
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Maintainer: Freemor <freemor@freemor.ca>
pkgname=hexchat
pkgver=2.14.2.r9.ged553301
pkgrel=1.parabola1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference'
arch=('i686' 'x86_64' 'armv7h')
url='https://hexchat.github.io/'
license=('GPL')
depends=('gtk2' 'openssl' 'dbus-glib' 'lua' 'python-cffi'
'libcanberra' 'libnotify' 'libproxy' 'pciutils'
'hicolor-icon-theme' 'desktop-file-utils' 'sound-theme-freedesktop' 'iso-codes')
makedepends=('git' 'perl' 'python' 'meson')
optdepends=('enchant: for spell check'
'perl: for perl plugin'
'python: for python plugin')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("git+https://github.com/hexchat/hexchat.git" 'restore_ctrl-w.patch')
sha256sums=('SKIP'
'f78f986a064e6c5a8713a219fa042c94bb2b0236869d33b48801faedc9cef63e')
pkgver() {
cd "hexchat"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd hexchat
# Remove nonfree browser references
sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
sed -i '\|NAME Open Link| s|firefox -new-window %s\\n\\n";|iceweasel -new-window %s\\n\\n"\\\n "NAME Open Link in a new Icecat Window\\n" "CMD !icecat -new-window %s\\n\\n";|' src/common/hexchat.c
#Restore CTRL-W
patch -p1 src/fe-gtk/menu.c ../restore_ctrl-w.patch
}
build() {
arch-meson hexchat build \
-Dwith-lua='lua' \
-Dwith-text='true'
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
}
# vim: ts=2 sw=2 et:
|
