blob: f52c99df330955fa053e43beb01a03cbaa60cd93 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# $Id$
# Maintainer (Arch): Evangelos Foutras <evangelos@foutrelis.com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Sebastien Piccand <sebcactus gmail com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=('handbrake' 'handbrake-cli')
pkgver=1.0.7
pkgrel=2.parabola2
arch=('i686' 'x86_64' 'armv7h')
url="https://handbrake.fr/"
license=('GPL')
makedepends=('intltool' 'python2' 'yasm' 'wget' 'bzip2' 'gcc-libs' 'libnotify'
'gst-plugins-base' 'gtk3' 'dbus-glib' 'fribidi' 'libass' 'lame'
'fontconfig' 'freetype2' 'libxml2' 'libogg' 'libvorbis' 'cmake'
'libtheora' 'libsamplerate' 'ffmpeg' 'x264' 'libx264' 'x265'
'libvpx' 'libdvdnav' 'jansson' 'librsvg' 'libgudev'
'libdvdread' 'libbluray')
source=(https://handbrake.fr/mirror/HandBrake-$pkgver.tar.bz2
handbrake-fix-missing-x265-link-flag.patch
handbrake-no-download.patch
handbrake-supress-clip_id.patch)
sha256sums=('ffdee112f0288f0146b965107956cd718408406b75db71c44d2188f5296e677f'
'05e212e76b6e0b94a04de02cbeb7bf9db607059e19297b5bd3d0d143135285c4'
'd8116caa83f870803581f0d02e1302b3b8990479d446e4c73bedd35bed531042'
'6407a96c59baa030a4e5fa46c53ddb3e841c7d4787613d391e032a62600d527f')
prepare() {
cd "$srcdir/HandBrake-$pkgver"
# https://bugs.gentoo.org/show_bug.cgi?id=552792
patch -Np1 -i ../handbrake-fix-missing-x265-link-flag.patch
patch -Np1 -i ../handbrake-no-download.patch
patch -Np1 -i ../handbrake-supress-clip_id.patch
# Use more system libs
# Bundled libbluray is kept because it is patched locally
for _lib in ffmpeg x265 libvpx libdvdnav libdvdread; do
sed -i "/MODULES += contrib\/$_lib/d" make/include/main.defs
done
}
build() {
cd "$srcdir/HandBrake-$pkgver"
./configure \
--prefix=/usr \
--disable-gtk-update-checks
make -C build
}
package_handbrake() {
pkgdesc="Multithreaded video transcoder"
depends=('bzip2' 'gcc-libs' 'gst-plugins-base' 'libnotify' 'dbus-glib'
'fribidi' 'libass' 'lame' 'gtk3' 'fontconfig' 'freetype2' 'libxml2'
'libogg' 'libvorbis' 'libtheora' 'libsamplerate' 'ffmpeg' 'libx264'
'x265' 'libvpx' 'libdvdnav' 'jansson' 'librsvg' 'libgudev'
'desktop-file-utils' 'hicolor-icon-theme')
optdepends=('gst-plugins-good: for video previews'
'gst-libav: for video previews')
cd "$srcdir/HandBrake-$pkgver/build"
make DESTDIR="$pkgdir" install
rm "$pkgdir/usr/bin/HandBrakeCLI"
}
package_handbrake-cli() {
pkgdesc="Multithreaded video transcoder (CLI)"
depends=('bzip2' 'gcc-libs' 'zlib' 'fribidi' 'libass' 'lame' 'libxml2'
'libtheora' 'libsamplerate' 'ffmpeg' 'libx264' 'x265' 'libvpx'
'libdvdnav' 'jansson')
cd "$srcdir/HandBrake-$pkgver/build"
install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
}
# vim:set ts=2 sw=2 et:
|
