blob: e917e064ca97f415523ff84a4e73a2c457618615 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# parabola changes and rationale:
# - removed unace and unrar recommendation
pkgname=file-roller
pkgver=3.36.2
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Create and modify archives"
pkgdesc+=", without nonfree unace and unrar recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(yelp-tools git libnautilus-extension meson appstream-glib)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
'lrzip: lrzip archive support'
'squashfs-tools: squashfs image support')
groups=(gnome)
_commit=eef4df4c857520ac81b1514d3b923e88855ce669 # tags/3.36.2^0
source=("git+https://gitlab.gnome.org/GNOME/file-roller.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
}
build() {
arch-meson $pkgname build
ninja -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
|
