blob: f834dafe3017a12a1aa4ab8beeebca529d526f94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Jochem Kossen <j.kossen@home.nl>
# NOTE: if building for armv7h, you may need to pass -N to libremakepkg,
# otherwise check() could fail
pkgname=fakeroot
pkgver=1.24
pkgrel=2
pkgrel+=.parabola1
pkgdesc='Tool for simulating superuser privileges'
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
url='https://packages.debian.org/fakeroot'
install=fakeroot.install
depends=(glibc filesystem sed util-linux sh)
makedepends=(po4a)
checkdepends=(sharutils)
source=("https://deb.debian.org/debian/pool/main/f/$pkgname/${pkgname}_${pkgver}.orig.tar.gz"
'silence-dlerror.patch')
sha256sums=('2e045b3160370b8ab4d44d1f8d267e5d1d555f1bb522d650e7167b09477266ed'
'347f6496c93ed0d91dcb554db92602b50520a16308e3b8bc33822bd69966267b')
prepare() {
cd $pkgname-$pkgver
patch -p1 -i "$srcdir"/silence-dlerror.patch
./bootstrap
# fix chmod_dev, mknod and touchinstall tests
sed -e 's/\^b/\^-/' \
-e 's/\<root\>/$USER/' \
-i test/t.{chmod_dev,mknod,touchinstall}
}
build() {
cd $pkgname-$pkgver
# SYSV IPC makes fakeroot fail with ARM emulation
# https://labs.parabola.nu/issues/2775
# https://archlinuxarm.org/forum/viewtopic.php?p=63781
if [ $CARCH = armv7h ]; then
ipc=tcp
else
ipc=sysv
fi
./configure --prefix=/usr \
--libdir=/usr/lib/libfakeroot \
--disable-static \
--with-ipc=$ipc
make
cd doc
po4a -k 0 --rm-backups --variable 'srcdir=../doc/' po4a/po4a.cfg
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -dm755 "$pkgdir/etc/ld.so.conf.d/"
echo '/usr/lib/libfakeroot' > "$pkgdir/etc/ld.so.conf.d/fakeroot.conf"
# install README for sysv/tcp usage
install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
}
|
